Sorting columns based on date in vba

[Sayan2795]

Hi,
I need to sort columns of data which are arranged as following

B1-10/2/2018
C1-11/2/2018
D1-12/2/2018

AND BELOW THEM IS DATA
The dates are the data headers
I need to sort the columns A,B,C,D such that the column with recent date comes first with the data and so on
Please help
Thank you

 

[Peter_SSs]

Assuming ...
- no blanks in the header row to the right of B1
- that the dates are actual dates (numbers) not text
- no duplicate date headers
... see if this does what you want.

Test in a copy of your workbook.

Sub Sort_Columns()
  Dim rHdrs As Range
  Dim SL As Object
  Dim i As Long, cols As Long
  Dim sNewHdrs
  
  Set SL = CreateObject("System.Collections.Sortedlist")
  Set rHdrs = Range("B1", Range("B1").End(xlToRight))
  cols = rHdrs.Columns.Count
  For i = 1 To cols
    SL.Add rHdrs.Cells(i).Value, i
  Next i
  Application.ScreenUpdating = False
  Columns("B").Resize(, cols).Insert
  sNewHdrs = rHdrs.Address
  For i = 0 To SL.Count - 1
    Range(sNewHdrs).Columns(SL.getbyindex(i)).EntireColumn.Cut Destination:=Range("B1").Offset(, cols - 1 - i)
  Next i
  Application.ScreenUpdating = True
End Sub