customizing msgbox in vba

[lezawang]

Hi
Can I customize msgbox, for example instead of [ok] I change it to [yes]. Thank you very much.

 

[Joe4]

There is a Yes/No and a Yes/No/Cancel option (see this link for all the options: https://docs.microsoft.com/en-us/office/vba/language/reference/user-interface-help/msgbox-function, specifically the buttons argument and all the options they list.)

But I do not believe you can create your own custom options for that in a MsgBox. If you want anything other than the options listed, I think you would need to create your own custom form.

 

[Rick Rothstein]

But I do not believe you can create your own custom options for that in a MsgBox. If you want anything other than the options listed, I think you would need to create your own custom form.

Creating a UserForm would probably be best, but there is a way to create your own "Message Box" although when I used to post it, some of the other volunteers told me there was problems with it. I am not sure what those problems are as I have never had a problem using this technique. With that warning stated upfront, here is a sample programmer created message box to demonstrate the possibilities...

[table="width: 500"]
[tr]
	[td]Sub MessageBoxAlternative()
  Const SheetID As String = "_Buttonz"
  Dim btnDlg As DialogSheet
   
  Application.ScreenUpdating = False
  On Error Resume Next
  Application.DisplayAlerts = False
  ActiveWorkbook.DialogSheets(SheetID).Delete
  Application.DisplayAlerts = True
  Err.Clear
   
  Set btnDlg = ActiveWorkbook.DialogSheets.Add
   
  With btnDlg
    .Name = SheetID
    .Visible = xlSheetHidden
     
    With .DialogFrame
      .Height = 100
      .Width = 280
      .Caption = "Please confirm..."
    End With
     
    With .Buttons("Button 2")
      .BringToFront
      .Height = 20
      .Width = 60
      .Caption = "Yes, please"
    End With
     
    With .Buttons("Button 3")
      .BringToFront
      .Height = 30
      .Width = 60
      .Caption = "No, thanks"
    End With
     
    .Labels.Add 100, 50, 100, 100
    .Labels(1).Caption = "Are you sure you want to move to the next sheet?"
    Application.ScreenUpdating = True
     
    If .Show = True Then
      MsgBox "Your ''Yes, please'' code goes here", 64, "Yes was clicked"
    Else
      MsgBox "Your ''No, thanks'' code goes here", 64, "No was clicked"
    End If
     
    Application.DisplayAlerts = False
    .Delete
    Application.DisplayAlerts = True
   
  End With
End Sub[/td]
[/tr]
[/table]

NOTE
-----------------
You can find more information about this by doing a Google search for...

Excel Dialog Sheets

 

[My Aswer Is This]

Here is a message box with Yes or No
Is this what you want:

Sub My_Message()
'Modified  10/3/2018  5:08:57 PM  EDT
Dim ans As String
ans = MsgBox("Are your sure you want to do this?", vbYesNo)
If ans = vbYes Then MsgBox "You answered Yes"
If ans = vbNo Then MsgBox "You answered No"
End Sub