Calculating IF formula for Tax & NI Deductions..
Results 1 to 3 of 3

Thread: Calculating IF formula for Tax & NI Deductions..
Thanks Thanks: 0 Likes Likes: 0

  1. #1
    New Member
    Join Date
    Apr 2019
    Posts
    1
    Post Thanks / Like
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)

    Lightbulb Calculating IF formula for Tax & NI Deductions..

    Hi All,


    Any help is appreciated, I've been playing about with this trying to get the formulas right, assuming an IF formula, but not sure how to separate if it requires an answer between a certain range.


    For example, I'm trying to write cell formulas so whatever Gross income is entered it works out what level tax and NI contributions, less any voluntary contributions, resulting in net pay.


    I'm hitting a wall with the following:


    1) Tax Levels Amount
    Basic Rate Up to £32,000.00 (20%)
    Upper rate £32,000.01 - £150,000.00 (40%)
    Additional Rate £150,000.01 upward (45%)

    I can see the following for the basic rate tax as:
    =If(B8<=E3,B8*F3,B8*F3)
    B8 being Taxable Income after deduction of Personal Allowance


    But as soon as i try to qualify a range, ie: If Taxable Income above £32k but below £150k deduct 40%


    and the same for 45% on anything above £150k


    then i need to figure how to assign each tax bracket deduction based on the level of taxable income, IE, under £32k level 1, over £32k but under £150k=level 2 and so on..






    2) National Insurance Levels Lower Upper
    0% charged between £0.00 and £154.99
    12% charged between £155.00 and £827.00
    2% charged anything over £827.00


    On a similar basis as above, trying to work out how to apply each at the relevant levels.


    3)
    If i contribute £1 to my workplace pension, then the employer contributes £2, etc.




    ALL & Any assistance is Greatly appreciated.


    Many Thanks all in Advance..


    KJ

  2. #2
    Board Regular tyija1995's Avatar
    Join Date
    Feb 2019
    Posts
    647
    Post Thanks / Like
    Mentioned
    14 Post(s)
    Tagged
    4 Thread(s)

    Default Re: Calculating IF formula for Tax & NI Deductions..

    Hello,

    You can nest the IF function so that it fulfils multiple criteria, I assume that if a gross income is say £40,000 then the income tax will be 20%(32000) + 40%(40000 - 32000) which results in 6400 + 3200 = £9600

    Going on this basis you can also use a SUMPRODUCT formula and set up some tables before hand to assist with the calculations.

    For example to work out the National Insurance based on your values and a 40k gross income:
    =SUMPRODUCT((40000/52>{0;155;827})*(40000/52-{0;155;827})*({0;0.12;-0.1}))*52
    This returns £3832.80 (National insurance paid per annum) take off the *52 at the end if you want it weekly.

    Similar logic can be applied to the income tax part, you can set up an array for the bracket values to make it easier so instead of having {0;155;827} you might want B1:B3 (where B1=0, B2=155, B3=827)

    I hope this makes sense. Let me know if you need anything else clearing up.

    Also it might be worth taking off the pension from the income before hand as that is free from tax(?)
    √-1 2³ ∑ π
    …And it was delicious!

  3. #3
    Board Regular
    Join Date
    Feb 2002
    Location
    Calgary, Alberta Canada
    Posts
    3,733
    Post Thanks / Like
    Mentioned
    3 Post(s)
    Tagged
    1 Thread(s)

    Default Re: Calculating IF formula for Tax & NI Deductions..

    N.B.
    1. It is not necessary to use the Named Ranges but it makes the formula easier to read.
    The 2a part is just the name of the sheet where I prepared the example.
    The 3 SumProduct formulas are all the same; the ranges are just shown differently.






    Excel 2010
    ABCDEF
    1Amount50,000.00BracketsRateRate_Diff
    2Tax13,600.00020%20%
    313,600.0032,00040%20%
    413,600.00150,00045%5%
    513,600.00
    613,600.00
    7

    2a



    Worksheet Formulas
    CellFormula
    F2=E2-N(E1)
    B2=SUMPRODUCT(--(B1>rB),B1-rB,rDiff)
    B3=SUMPRODUCT(--(B1>{0;32000;150000}),B1-{0;32000;150000},{0.2;0.2;0.05})
    B4=SUMPRODUCT(--(B1>D2:D4),B1-D2:D4,F2:F4)
    B5=(B1>0)*B1*0.2+(B1>32000)*(B1-32000)*0.2+(B1>150000)*(B1-150000)*0.05
    B6=IF(AND(B1>0,B1<=32000),B1*0.2,IF(AND(B1>32000,B1<=150000),(B1-32000)*0.4+6400,IF(B1>150000,(B1-150000)*0.45+47200)))

    Worksheet Defined Names
    NameRefers To
    '2a'!rB='2a'!$D$2:$D$4
    '2a'!rDiff='2a'!$F$2:$F$4
    Last edited by Dave Patton; Apr 17th, 2019 at 11:59 AM.

Some videos you may like

User Tag List

Tags for this Thread

Like this thread? Share it with others

Like this thread? Share it with others

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •