If you fancy trying suggestion by @Jaafar Tribak, here is some code to help
Test on a COPY of your workbook! - ensure that there are no shapes or images etc in sheet2 before running the code
(the workbook must have been saved before running the VBA - it is using the workbook path to save the gif)

The code creates the camera image, creates a chart , places image in chart, exports chart as gif, loads it automatically into the userform when activated, deletes all images created

To test
1. Create a UserForm containing an image frame named Image1
2. Place VBA into that userform's code window
3. Show the userform

Code:
Private Sub UserForm_Activate()
    Call LoadImage
End Sub

Private Sub LoadImage()
    Dim C As Chart, R As Range, FName As String, W As Worksheet
    Set W = Sheets("Sheet2")
    Set R = W.Range("A1:C21")
'add temp chart
    W.Shapes.AddChart2(262, xl3DPie).Select
    Set C = W.ChartObjects(1).Chart
'Resize chartobject
    With C.Parent
        .Width = R.Width
        .Height = R.Height
    End With
'Copy the cells as bitmap and paste into the chart
    R.CopyPicture xlScreen, xlBitmap
    C.Paste
'Export
    FName = ThisWorkbook.Path & "\temp.gif"
    C.Export FName, "GIF", False
'Load into the userform
    UserForm1.Image1.Picture = LoadPicture(FName, 0, 0)
'delete temp image and chart in sheet
    Do While W.Shapes.Count > 0
        W.Shapes(1).Delete
    Loop
End Sub