Loop through all objects in a frame

[bradyboyy88]

Hi,

I am curious if there is a way to loop through all control objects in a userform frame or do I have to loop through all objects in the userform and look for that particular frame as a parent? For instance, can I use a for each item in frame type loop?

My Current code draws a mistype error:

[COLOR=#333333]
Option Explicit


Public Sub Weekly_Button()


    HideAllSubFrames (Userform1.TestFrame)


End Sub




Public Sub HideAllSubFrames(ParentFrame As MSForms.FRAME)


    Dim ObjectList As Variant
    
    For Each ObjectList In ParentFrame.Controls
        If TypeName(ObjectList.Type) = "Frame" Then
            ObjectList.Visible = False
        End If
    Next
End Sub[/COLOR]

 

[Tom Urtis]

Frame controls are like any other control that has a name, so assuming your frame control of interest is named Frame1, and further assuming you are clicking CommandButton1 on your UserForm to loop through the controls in Frame1, this will get you started to show how to do that with a message box that identifies each control's name that resides in Frame1.

Private Sub CommandButton1_Click()
Dim ctrl As Control
For Each ctrl In Frame1.Controls
MsgBox ctrl.Name
Next
End Sub

 

[Domenic]

Also, you might be interested to know that the reason you're getting a type mismatch error is that you've enclosed the argument for the calling procedure within parenthesis. You'll need to remove them.

Public Sub Weekly_Button()

    HideAllSubFrames UserForm1.TestFrame

End Sub

As you already know, the Call keyword is optional when calling a procedure. When specified, the argument list must be enclosed in parenthesis. However, if you omit them, as you've done in your case, you also have to omit the parenthesis from the argument list. Here's the reference for the Call statement...

https://docs.microsoft.com/en-us/office/vba/Language/Reference/User-Interface-Help/call-statement

So, in your case, while you've omitted the Call keyword, you've included the parenthesis around the argument. And, since the argument is an object, its default property is evaluated, which in this case is the Controls object. Hence the type mismatch error.

By the way, Type is not a property of the Control object. So you can just pass the object itself to TypeName...

If [COLOR=#333333]TypeName(ObjectList) = "Frame" Then[/COLOR]

 

[bradyboyy88]

Thank you for the information! It has helped a lot!