Validate data pasted to a textbox
Results 1 to 6 of 6

Thread: Validate data pasted to a textbox

  1. #1
    Board Regular
    Join Date
    Feb 2006
    Location
    NJ, USA
    Posts
    350
    Post Thanks / Like
    Mentioned
    2 Post(s)
    Tagged
    0 Thread(s)

    Default Validate data pasted to a textbox

    Simple question, I hope.

    I need to be able to check a textbox to see if the data pasted to it is numeric.

    I know to use the isnumeric function, I just can't figure out which event to put it under.

    I don't need much help, just help in figuring out how to check the box if someone does a CTL + v or a right-click and paste.


    Thanks in advance.
    - Posting guidelines, forum rules and terms of use

    - Try searching for your answer first, see how

    - Read the FAQs

    - List of BB codes

    Also, when asking questions, please be as detailed as possible, and If I have helped you, please let me know.
    I don't require thanks, but acknowledgement is nice

  2. #2
    Board Regular
    Join Date
    Jul 2012
    Location
    Hampshire, UK
    Posts
    4,941
    Post Thanks / Like
    Mentioned
    21 Post(s)
    Tagged
    1 Thread(s)

    Default Re: Validate data pasted to a textbox

    Hi,
    try the change event & see if this does what you want

    Code:
    Private Sub TextBox1_Change()
        With TextBox1
           If Len(.Text) And IsNumeric(.Text) Then MsgBox "Numeric"
        End With
    End Sub
    Dave

  3. #3
    Board Regular
    Join Date
    Feb 2006
    Location
    NJ, USA
    Posts
    350
    Post Thanks / Like
    Mentioned
    2 Post(s)
    Tagged
    0 Thread(s)

    Default Re: Validate data pasted to a textbox

    Thanks, worked like a charm!
    - Posting guidelines, forum rules and terms of use

    - Try searching for your answer first, see how

    - Read the FAQs

    - List of BB codes

    Also, when asking questions, please be as detailed as possible, and If I have helped you, please let me know.
    I don't require thanks, but acknowledgement is nice

  4. #4
    MrExcel MVP Rick Rothstein's Avatar
    Join Date
    Apr 2011
    Location
    New Jersey, USA
    Posts
    34,973
    Post Thanks / Like
    Mentioned
    91 Post(s)
    Tagged
    33 Thread(s)

    Default Re: Validate data pasted to a textbox

    Quote Originally Posted by Richard U View Post
    Thanks, worked like a charm!
    Did it really? Try pasting &HEAD in the TextBox and tell me if you got the result you wanted.

    IsNumeric is a terrible function to test whether a text value is actually a number. Here is something I have been posting for several years now that explains the problem and gives some functions you can use within your code to test for the type of numeric value (integer or floating point) you are interested in...

    I usually try and steer people away from using IsNumeric to "proof" supposedly numeric text. Consider this (also see note below):

    Code:
    ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")
    Most people would not expect THAT to return True. IsNumeric has some "flaws" in what it considers a proper number and what most programmers are looking for.

    I had a short tip published by Pinnacle Publishing in their Visual Basic Developer magazine that covered some of these flaws. Originally, the tip was free to view but is now viewable only by subscribers..

    Basically, it said that IsNumeric returned True for things like -- currency symbols being located in front or in back of the number as shown in my example (also applies to plus, minus and blanks too); numbers surrounded by parentheses as shown in my example (some people use these to mark negative numbers); numbers containing any number of commas before a decimal point as shown in my example; numbers in scientific notation (a number followed by an upper or lower case "D" or "E", followed by a number equal to or less than 307 -- the maximum power of 10 in VB); and Octal/Hexadecimal numbers (&H for Hexadecimal, &O or just & in front of the number for Octal).

    NOTE:
    ======
    In the above example and in the referenced tip, I refer to $ signs and commas and dots -- these were meant to refer to your currency, thousands separator and decimal point symbols as defined in your local settings -- substitute your local regional symbols for these if appropriate.

    As for your question about checking numbers, here are two functions that I have posted in the past for similar questions..... one is for digits only and the other is for "regular" numbers (the code is simple enough that it can be pulled from the function "housing" and used directly inside your own code):

    Code:
    Function IsDigitsOnly(Value As String) As Boolean
        IsDigitsOnly = Len(Value) > 0 And Not Value Like "*[!0-9]*"
    End Function
    
    Function IsFloatingPoint(ByVal Value As String) As Boolean
        '   Leave the next statement out if you don't
        '   want to provide for plus/minus signs
        If Value Like "[+-]*" Then Value = Mid$(Value, 2)
        IsFloatingPoint = Not Value Like "*[!0-9.]*" And Not Value Like "*.*.*" And Len(Value) > 0 And Value <> "."
    End Function
    Here are revisions to the above functions that deal with the local settings for decimal points (and thousand's separators) that are different than used in the US (this code works in the US too, of course).

    Code:
    Function IsNumber(ByVal Value As String) As Boolean
      Dim DP As String
      '   Get local setting for decimal point
      DP = Format$(0, ".")
      '   Leave the next statement out if you don't
      '   want to provide for plus/minus signs
      If Value Like "[+-]*" Then Value = Mid$(Value, 2)
      IsNumber = Not Value Like "*[!0-9" & DP & "]*" And Not Value Like "*" & _
                 DP & "*" & DP & "*" And Len(Value) > 0 And Value <> DP
    End Function
    I'm not as concerned by the rejection of entries that include one or more thousand's separators, but we can handle this if we don't insist on the thousand's separator being located in the correct positions (in other words, we'll allow the user to include them for their own purposes... we'll just tolerate their presence).

    Code:
    Function IsNumber(ByVal Value As String) As Boolean
      Dim DP As String
      Dim TS As String
      '   Get local setting for decimal point
      DP = Format$(0, ".")
      '   Get local setting for thousand's separator
      '   and eliminate them. Remove the next two lines
      '   if you don't want your users being able to
      '   type in the thousands separator at all.
      TS = Mid$(Format$(1000, "#,###"), 2, 1)
      Value = Replace$(Value, TS, "")
      '   Leave the next statement out if you don't
      '   want to provide for plus/minus signs
      If Value Like "[+-]*" Then Value = Mid$(Value, 2)
      IsNumber = Not Value Like "*[!0-9" & DP & "]*" And Not Value Like "*" & _
                 DP & "*" & DP & "*" And Len(Value) > 0 And Value <> DP
    End Function
    Closing Note
    -----------------------------
    The above functions for checking if text is a number were written back in my volunteer days for the compiled version of Visual Basic and while it all still works in Excel's VBA, you could also reach out to the worksheet's ISNUMBER function and test the text for being a number that way (its probably a tad slower to do it that way, but probably not enough to worry about unless used in a huge loop of some kind).

    Code:
    Function IsNumber(Value) As Boolean
      IsNumber = Evaluate("ISNUMBER(0+""" & Value & """)")
    End Function
    Note though that this function will consider numbers in powers of 10 format (such as 123e4) to be a number.
    Last edited by Rick Rothstein; Jun 20th, 2019 at 02:47 PM.
    Rick's "mini" blog... http://www.excelfox.com/forum/f22/
    .
    Want to post a small screen shot? See Part B here.

  5. #5
    Board Regular
    Join Date
    Jul 2012
    Location
    Hampshire, UK
    Posts
    4,941
    Post Thanks / Like
    Mentioned
    21 Post(s)
    Tagged
    1 Thread(s)

    Default Re: Validate data pasted to a textbox

    Quote Originally Posted by Richard U View Post
    Thanks, worked like a charm!
    Pleased If suggestion works for your particular need but do take time to read Ricks post.

    Dave

  6. #6
    Board Regular
    Join Date
    Feb 2006
    Location
    NJ, USA
    Posts
    350
    Post Thanks / Like
    Mentioned
    2 Post(s)
    Tagged
    0 Thread(s)

    Default Re: Validate data pasted to a textbox

    Wow, thank you, this is pure gold.

    The isnumeric would have worked for what I was using, but this is much much better, and bulletproof. Thank you so much Rick.
    - Posting guidelines, forum rules and terms of use

    - Try searching for your answer first, see how

    - Read the FAQs

    - List of BB codes

    Also, when asking questions, please be as detailed as possible, and If I have helped you, please let me know.
    I don't require thanks, but acknowledgement is nice

Some videos you may like

User Tag List

Tags for this Thread

Like this thread? Share it with others

Like this thread? Share it with others

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •