VBA to sum for each row

[MNet23]

I'm fairly new to vba and am trying to figure out how to get the sum for each row.
Right now I'm stuck either getting the sum for just the 1st row or all the rows combined.
can someone explain to me how to do the code to get the sum for each row please

1	B	C	D	E	Total
2	75	71	68	67	281
3	69	68	72	73	281
4	75	72	75	74	281
5	73	71	73	69	281

<tbody>
</tbody>

 

[lrobbo314]

How about this?

Sub Totals()
Dim r As Range:     Set r = Range("B2:E" & Range("B" & Rows.Count).End(xlUp).Row)
Dim Total As Range: Set Total = r.Offset(, 4).Resize(r.Rows.Count, 1)

With Total
    .FormulaR1C1 = "=SUM(RC[-4]:RC[-1])"
    .Value = .Value
End With

End Sub

 

[JoeMo]

or this?

Sub SumRows()
Dim R As Range
Set R = Range("B2:E5")
For i = 1 To R.Rows.Count
    R.Rows(i).Cells(1, 5).Value = Evaluate("SUM(" & R.Rows(i).Address & ")")
Next i
End Sub

 

[jolivanes]

And another possibility.
Just in case Column F will not always be the "Total" Column.
This should work regardless which Column that will be.
I hope that you don't mind that this gives different totals from what you have in Post#1

Sub Maybe()
Dim j As Long, i As Long
j = Rows(1).Find("Total", , , 1).Column - 2
i = Cells(Rows.Count, 2).End(xlUp).Row
    With Range(Cells(2, j + 2), Cells(i, j + 2))
        .Formula = "=SUM(RC[-" & j & "]:RC[-1])"
        .Value = .Value
    End With
End Sub

 

[Yongle]

Here is another one for you

Do you want the formula in the cell ?

Sub asFormula()
    Dim r As Long
    For r = 2 To Cells(Rows.Count, "B").End(xlUp).Row
        Cells(r, "F").formula = Replace("=sum(B@:E@)", "@", r)
    Next
End Sub

Or the value ?
- same as above with Evaluate wrapped around it

Sub asValue1()
    Dim r As Long
    For r = 2 To Cells(Rows.Count, "B").End(xlUp).Row
        Cells(r, "F").formula = [COLOR=#008080]Evaluate([/COLOR]Replace("=sum(B@:E@)", "@", r)[COLOR=#008080])[/COLOR]
    Next
End Sub

Another way to get the value

Sub asValue2()
    Dim r As Long
    For r = 2 To Cells(Rows.Count, "B").End(xlUp).Row
        Cells(r, "F") = WorksheetFunction.Sum(Range("B" & r & ":E" & r))
    Next
End Sub

NOTE : above assume that the last entry in column B determines the range