How To Populate Strings Conditionally?

[xlmaniac]

Dear All,
I would like to populate strings based on the SKU & Store combinations.
The count of strings will be equal to # SKUs(Unique Count) X # Stores.
The strings could go into thousands/lakhs of rows.
I have the following sample data set across A1:B5.
IN A Column I have 3 Unique Count of SKUs and in Column B I Have 4 unique count of stores.
I would like to populate the strings(in this case it will be 12) in Column C.

SKU	Store	SKU-Store Strings
1	a	1a
2	b	1b
3	c	1c
	d	1d
		2a
		2b
		2c
		2d
		3a
		3b
		3c
		3d Could somebody help me out with the solution Pls? Regards

<tbody>
</tbody>

 

[Fluff]

How about

Sub xlmaniac()
   Dim Ary1 As Variant, Ary2 As Variant, Nary As Variant
   Dim r1 As Long, r2 As Long, nr As Long
   
   Ary1 = Range("A2", Range("A" & Rows.Count).End(xlUp)).Value2
   Ary2 = Range("B2", Range("B" & Rows.Count).End(xlUp)).Value2
   ReDim Nary(1 To UBound(Ary1) * UBound(Ary2), 1 To 1)
   For r1 = 1 To UBound(Ary1)
      For r2 = 1 To UBound(Ary2)
         nr = nr + 1
         Nary(nr, 1) = Ary1(r1, 1) & Ary2(r2, 1)
      Next r2
   Next r1
   Range("C2").Resize(nr).Value = Nary
End Sub

 

[xlmaniac]

How about

Sub xlmaniac()
   Dim Ary1 As Variant, Ary2 As Variant, Nary As Variant
   Dim r1 As Long, r2 As Long, nr As Long
   
   Ary1 = Range("A2", Range("A" & Rows.Count).End(xlUp)).Value2
   Ary2 = Range("B2", Range("B" & Rows.Count).End(xlUp)).Value2
   ReDim Nary(1 To UBound(Ary1) * UBound(Ary2), 1 To 1)
   For r1 = 1 To UBound(Ary1)
      For r2 = 1 To UBound(Ary2)
         nr = nr + 1
         Nary(nr, 1) = Ary1(r1, 1) & Ary2(r2, 1)
      Next r2
   Next r1
   Range("C2").Resize(nr).Value = Nary
End Sub

Simply mesmerizing solution!!
It is working like a magic!!
Thank you so much for your kind support.
Really appreciate your help!!

 

[Fluff]

You're welcome & thanks for the feedback