HELP with INDEX formula. Need IMMEDIATELY

[Tungsten]

I created a table to record ordering items, and have 2 columns (a Date, and a Qty) for each week of the year, per quarter, to record the Date Ordered and Quantity Ordered. I have 2 columns (at the end of each quarter) which I want the Last Date Ordered to appear in one column, and Last QTY Ordered to appear in another column.

I have the headers labeled (WK 1 Order Date, WK 1 Order QTY; WK 2 Order Date, WK 2 Order QTY... through Week 13 (for the qtr). At end of each quarter, I want the Last Date Ordered column to display only the last date entered, and the Last QTY Ordered to only display the last quantity entered.

What formula do I use in the Last Date Ordered column to skip the the Order QTY cells, and display the last date entered? (same thing for the Last Qty Ordered skipping the Date Ordered cells)?

I have used the INDEX/ COUNT functions to display the last data entered, but need it to skip ever-other cell to display only the Date/ and only the Quantity in the respective cells.

WK 1 ORDER DATE WK 1 ORDER QTY WK 2 ORDER DATE WK 2 ORDER QTY WK 3 ORDER DATE WK 3 ORDER QTY WK 4 ORDER DATE WK 4 ORDER QTY WK 5 ORDER DATE WK 5 ORDER QTY WK 6 ORDER DATE WK 6 ORDER QTY WK 7 ORDER DATE WK 7 ORDER QTY WK 8 ORDER DATE WK 8 ORDER QTY WK 9 ORDER DATE WK 9 ORDER QTY WK 10 ORDER DATE WK 10 ORDER QTY WK 11 ORDER DATE WK 11 ORDER QTY WK 12 ORDER DATE WK 12 ORDER QTY WK 13 ORDER DATE WK 13 ORDER QTY LAST ORDER DATE <tbody> </tbody>

LAST ORDER QTY

07/21/19 100 07/28/19 200 4/9 <tbody> </tbody>

200 <tbody> </tbody>

<tbody>
</tbody>

 

[Tungsten]

THIS Is the formula I'm using in the Last Order Date cell: =IFERROR(INDEX(Order[@[WK 1 ORDER DATE]:[WK 13 ORDER QTY]],(COLUMNS(G4:G4)-1)*2,COUNT(Order[@[WK 1 ORDER DATE]:[WK 13 ORDER QTY]])),"")

 

[Peter_SSs]

Welcome to the MrExcel board!

Firstly, in relation to the urgency of the title of your thread, I suggest that you have a look at the Forum Use Guidelines, particularly 5g and 5h in section A.

You could try these.
Last order date
=LOOKUP(9.99E+307,Order[@[WK 1 ORDER QTY]:[WK 13 ORDER QTY]],Order[@[WK 1 ORDER DATE]:[WK 13 ORDER DATE]])

Last order quantity
=LOOKUP(9.99E+307,Order[@[WK 1 ORDER QTY]:[WK 13 ORDER QTY]])

 

[Tungsten]

It works. The formulas still read all the data entered (when the QTY isn't entered, the Date is is misread - and the same with the quantity); when both the date and quantity is entered, then both columns display correctly.

Thank you for the assistance (and for the reminder of forum guidelines).

 

[Peter_SSs]

It works.

Good news.

(when the QTY isn't entered, the Date is is misread - and the same with the quantity);

If you want to avoid that, try these versions instead.

Date
=IF([@[LAST ORDER QTY]]="","",LOOKUP(9.99E+307,Order[@[WK 1 ORDER QTY]:[WK 13 ORDER QTY]],Order[@[WK 1 ORDER DATE]:[WK 13 ORDER DATE]]))

QTY
=IF(MOD(COUNT(Order[@[WK 1 ORDER DATE]:[WK 13 ORDER QTY]]),2)=0,LOOKUP(9.99E+307,Order[@[WK 1 ORDER QTY]:[WK 13 ORDER QTY]]),"")