Product Totals

[Lucy89]

Hi please see the photo in the link;

https://ibb.co/RPmLYTz

Is it possible so that A16:A24 will display a product code and C16:C24 will show the total amount of each product?

 

[Toadstool]

Lucy89,

The tricky part here is getting the list of unique Product Codes (as I assume you do not yet have access to the new UNIQUE function).

This solution:

1. Assumes your Product Codes are in A2 through A12 (as suggested by the screenshot).
2. Requires that cell A15 does not contain a value which may match a Product Code.
3. The longer formula with INDEX MATCH and COUNTIF is an array formula so must be entered using Ctrl-Shift-Enter so that Excel automatically generate the curly brackets. The SUMIFS just needs to be entered with the Enter key.

	A	B	C
1	Product Codes		Parts Used
2	SBR 257		4
3	FSD 014		5
4	FSD 014		4
5	SBR 001		1
6	SPR 385		5
7	SBR 257		1
8
16	SBR 257		5
17	FSD 014		9
18	SBR 001		1
19	SPR 385		5
20
21
22
23
24

<colgroup><col><col><col></colgroup><tbody>
</tbody>

Cell A16 contains
=IFERROR(INDEX($A$2:$A$12, MATCH(0, COUNTIF($A$15:A15, $A$2:$A$12&"") + IF($A$2:$A$12="",1,0), 0)), "")
which is entered using CTRL-Shift-Enter to generate
{=IFERROR(INDEX($A$2:$A$12, MATCH(0, COUNTIF($A$15:A15, $A$2:$A$12&"") + IF($A$2:$A$12="",1,0), 0)), "")}
Copy down to A24

Cell C16 contains
=IF(A16="","",SUMIFS($C$2:$C$12,$A$2:$A$12,A16))
Copy down to C24

 

[Lucy89]

Toadstool thank you thank you thank you! This is perfect, fantastic

I like to think I know a little about excel formulas but what’s all this curly brackets thing about please?

 

[Toadstool]

Lucy,

An Array Formula lets you take a function which normally just acts on one cell and have it execute across a range of cells. It's important to note you can't type in those curly brackets as it's the Ctrl-Shift-Enter which tells Excel to treat it as an array formula and Excel puts in the curly brackets to show it has done so.
The Microsoft explanation may help and it can be found here: Array Formulae


If you'd rather avoid array formulae (which can be slow to run) then here's an alternative. Just enter
=IFERROR(INDEX($A$2:$A$12,MATCH(0,INDEX(COUNTIF($A$15:A15,$A$2:$A$12&""),),0)),"")
into A16 and copy down to A24. The SUMIFS statement in column C is unchanged.

	A	B	C
1	Product Codes		Parts Used
2	SBR 257		4
3	FSD 014		5
4	FSD 014		4
5	SBR 001		1
6	SPR 385		5
7	SBR 257		1
8
12
15
16	SBR 257		5
17	FSD 014		9
18	SBR 001		1
19	SPR 385		5
20

<tbody>
</tbody>

ProductCodes​

Worksheet Formulas Cell Formula A16 =IFERROR(INDEX($A$2:$A$12,MATCH(0,INDEX(COUNTIF($A$15:A15,$A$2:$A$12&""),),0)),"") C16 =IF(A16="","",SUMIFS($C$2:$C$12,$A$2:$A$12,A16)) <tbody> </tbody>

<tbody>
</tbody>

Regards,
Toadstool

 

[Lucy89]

Wonderful. I'll take a read. Once again thank you.

 

[Toadstool]

You're welcome!