add borders to range of cells that changes each day

[excel01noob]

Hi

In my team we have a daily set of data which we need to analyse and send to the teams members.
As the summary of analysed data is sent by email I want to send it in a way that the data has borders on it.


In terms of columns, it goes from column A to L.
In terms of rows, data will vary from day to day.

How can I insert a code that would do the borders for this data that changes each day ?

Thank you in advance

 

[excel01noob]

I'm using this code but the borders are being put to all cells between A to L

Sub borders()

Dim cell As Range

For Each cell In ActiveSheet.Range("A:L")

    With cell.Borders(xlEdgeLeft)
    .LineStyle = xlContinuous
    .ColorIndex = 0
    .TintAndShade = 0
    .Weight = xlThin
    End With
    With cell.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With cell.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With cell.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With

    Next cell

End Sub

 

[Peter_SSs]

Assuming that column A can be used to determine where the data ends, does this do what you want?

Sub Data_Borders()
  Columns("A:L").borders.LineStyle = xlNone
  With Range("A1", Range("A" & Rows.Count).End(xlUp)).Resize(, 12)
    .BorderAround xlContinuous, xlThin
    With .borders(xlInsideHorizontal)
      .LineStyle = xlContinuous
      .Weight = xlThin
    End With
    With .borders(xlInsideVertical)
      .LineStyle = xlContinuous
      .Weight = xlThin
    End With
  End With
End Sub

 

[excel01noob]

it worked perfectly, Peter.
thank you for that !

 

[Peter_SSs]

it worked perfectly, Peter.
thank you for that !

You are welcome. Thanks for the confirmation.