Return values for SaveWebFile

[KenCriss]

Found this piece of code which works well for downloading files from the web but am wondering if anyone know the return values...

Function SaveWebFile(ByVal vWebFile As String, ByVal vLocalFile As String) As Boolean

Dim oXMLHTTP As Object, i As Long, vFF As Long, oResp() As Byte

Set oXMLHTTP = CreateObject("msxml2.xmlhttp")

oXMLHTTP.Open "GET", vWebFile, False
oXMLHTTP.send
oResp = oXMLHTTP.ResponseBody

vFF = FreeFile
If Dir(vLocalFile) <> "" Then Kill vLocalFile
Open vLocalFile For Binary As #vFF
Put #vFF, , oResp
Close #vFF
Set oXMLHTTP = Nothing
End Function

I have tried calling it like this

If (SaveWebFile "https://xxxxxxx.com/whatever.zip", ThePath & "\PUpdate.zip") = True

...but if it fails, it does not necessarily come back with a False like I thought it would.

Any thoughts?

 

[John_w]

Although declared as 'function returning Boolean', the return value of SaveWebFile is never defined so it always returns False.

You could change it to check the XMLHttp.statusText property and return True or False, like this:

Function SaveWebFile(ByVal vWebFile As String, ByVal vLocalFile As String) As Boolean

    Dim oXMLHTTP As Object, i As Long, vFF As Long, oResp() As Byte
    
    Set oXMLHTTP = CreateObject("msxml2.xmlhttp")
    
    oXMLHTTP.Open "GET", vWebFile, False
    oXMLHTTP.send
    oResp = oXMLHTTP.ResponseBody
    
    Debug.Print oXMLHTTP.Status, oXMLHTTP.statusText
    
    If oXMLHTTP.statusText = "OK" Then
        vFF = FreeFile
        If Dir(vLocalFile) <> "" Then Kill vLocalFile
        Open vLocalFile For Binary As #vFF
        Put #vFF, , oResp
        Close #vFF
        SaveWebFile = True
    Else
        SaveWebFile = False
    End If
    
    Set oXMLHTTP = Nothing
    
End Function

 

[KenCriss]

I'll try it. thanks!