Avoir la date de la derniére modification de chaque feuille de mon fichier

[karen55]

Bonjour, je souhaite avoir via une macro la date de la derniére modification de chaque feuille de mon fichier excel et que le résultat soit regroupé dans une notre feuile que je vais appeler "mises à jours"

 

[Anthony47]

Essaye:

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim myMatch, myNext As Long
On Error GoTo GetOut
Application.EnableEvents = False
myMatch = Application.Match(Sh.Name, Sheets("mises à jours").Range("A1:A100"), False)
If IsError(myMatch) Then
    myNext = Sheets("mises à jours").Cells(Rows.Count, "A").End(xlUp).Row + 1
    Sheets("mises à jours").Cells(myNext, 1) = Sh.Name
    Sheets("mises à jours").Cells(myNext, 2) = Now
Else
    Sheets("mises à jours").Cells(myMatch, 2) = Now
End If
GetOut:
Application.EnableEvents = True
End Sub

A copier dans le module ThisWorkbook

La liste des feuilles (dans "mises à jours") est mise à jour lorsqu'une nouvelle feuille est modifiée

(Traduit via translate.google.com)

 

[karen55]

Essaye:

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim myMatch, myNext As Long
On Error GoTo GetOut
Application.EnableEvents = False
myMatch = Application.Match(Sh.Name, Sheets("mises à jours").Range("A1:A100"), False)
If IsError(myMatch) Then
    myNext = Sheets("mises à jours").Cells(Rows.Count, "A").End(xlUp).Row + 1
    Sheets("mises à jours").Cells(myNext, 1) = Sh.Name
    Sheets("mises à jours").Cells(myNext, 2) = Now
Else
    Sheets("mises à jours").Cells(myMatch, 2) = Now
End If
GetOut:
Application.EnableEvents = True
End Sub

A copier dans le module ThisWorkbook

La liste des feuilles (dans "mises à jours") est mise à jour lorsqu'une nouvelle feuille est modifiée

(Traduit via translate.google.com)

merci beaucoup pour ta réponse, en faite ce code donne la date et l'heure de la derniere modification de tous le fichier, moi ce que je cherche c'est d'avoir la date de modification de chaque feuille

 

[Anthony47]

merci beaucoup pour ta réponse, en faite ce code donne la date et l'heure de la derniere modification de tous le fichier, moi ce que je cherche c'est d'avoir la date de modification de chaque feuille

Mon code écrit dans la feuille "mises à jours" la date de la dernière modification de chaque feuille du fichier

MULTI_C21026.xlsm
	A	B	C
1	Nom du feuil	Dernière modification
2	mises à jours	28/10/2022 19:12
3	Foglio2	28/10/2022 19:11
4	Foglio1	28/10/2022 19:11
5
6
mises à jours

 

[Juan59000]

Mon code écrit dans la feuille "mises à jours" la date de la dernière modification de chaque feuille du fichier

MULTI_C21026.xlsm
	A	B	C
1	Nom du feuil	Dernière modification
2	mises à jours	28/10/2022 19:12
3	Foglio2	28/10/2022 19:11
4	Foglio1	28/10/2022 19:11
5
6
mises à jours

Bonjour,
Je me permets de revenir sur ce code, qui m'aide beaucoup mais j'aurais besoin d'une variante svp.
Ce code fait en sorte d'archiver toutes les modifications de toutes les feuilles. Comment peut-on faire en sorte :
=> qu'elle ne reprenne que la dernière modification (en écrasant les précédentes) ?
=> qu'elle ne soit active que sur certaines feuilles et pas d'autres ?

Merci beaucoup pour votre aide !

 

[Anthony47]

Le code ne garde déjà que la dernière modification, en écrasant les informations de modification précédentes.
Pour ignorer certaines feuilles, nous pouvons ajouter ces instructions à cet position:

Dim myMatch, myNext As Long
'Nouveau code >>>
Dim Ignore

Ignore = Array("SheetA", "Foglio5", "mises à jours")    '<<< Liste des feuilles à ignorer
If Not IsError(Application.Match(Sh.Name, Ignore, False)) Then Exit Sub
'<<< Fin du nouveau code

On Error GoTo GetOut
'etc etc

Modifiez la ligne marquée <<<

 

[Juan59000]

Bonjour,
Merci beaucoup de votre réponse. Je vais regarder pour intégrer votre proposition de code pour ignorer certaines feuilles.
J'ai vérifié et Excel recréée bien une ligne dès lors que la dernière ligne indiquant une modification n'est pas celle qui vient de l'être. A titre d'exemple, j'ai mis à jour successivement les feuilles "mises à jour", "1","2","3","4","5", puis j'ai ai remodifié la feuille "2", et Excel me recréée bien une nouvelle ligne :

Nom de la feuille	date de modification
mises à jours	26/04/2023 10:07​
1​	26/04/2023 10:04​
2​	26/04/2023 10:04​
3​	26/04/2023 10:04​
4​	26/04/2023 10:04​
5​	26/04/2023 10:05​
2​	26/04/2023 10:06​

 

[Anthony47]

Les feuilles ont généralement un nom, pas un numéro...

Pour vivre avec des noms numériques, modifiez cette ligne :

    Sheets("mises à jours").Cells(myNext, 1) = "'" & Sh.Name

Notez "'" & ajouté

 

[Juan59000]

Bonjour, juste pour vous remercier : je viens d'intégrer vos codes et ça marche nickel !
Bonne journée !