BINGO

[lrobbo314]

BINGO returns a 75 ball Bingo card.

=LAMBDA(
    VSTACK(
        {"B","I","N","G","O"},
        IF(SEQUENCE(5,5)=13,
            "FREE",
            FILTER(SORTBY(TRANSPOSE(SEQUENCE(5,15)),RANDARRAY(15)),SEQUENCE(15)<6)
        )
    )
)

BINGO
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1	B	I	N	G	O		B	I	N	G	O		B	I	N	G	O
2	11	26	41	56	71		10	25	40	55	70		1	16	31	46	61
3	3	18	33	48	63		9	24	39	54	69		10	25	40	55	70
4	1	16	FREE	46	61		15	30	FREE	60	75		14	29	FREE	59	74
5	8	23	38	53	68		3	18	33	48	63		15	30	45	60	75
6	13	28	43	58	73		7	22	37	52	67		11	26	41	56	71
7
8	B	I	N	G	O		B	I	N	G	O		B	I	N	G	O
9	7	22	37	52	67		14	29	44	59	74		5	20	35	50	65
10	3	18	33	48	63		8	23	38	53	68		11	26	41	56	71
11	4	19	FREE	49	64		11	26	FREE	56	71		10	25	FREE	55	70
12	2	17	32	47	62		15	30	45	60	75		14	29	44	59	74
13	5	20	35	50	65		10	25	40	55	70		7	22	37	52	67
Data

Cell Formulas
Range	Formula
A1:E6,M8:Q13,G8:K13,A8:E13,M1:Q6	A1	=BINGO()
Dynamic array formulas.

 

[smozgur]

Nice!

 

[lrobbo314]

Thanks, lol. Got Bingo on the brain.

 

[LogChief]

Your Bingo formula looks good, but I do see a problem with the randomness of numbers of across rows. You will notice that every number in the B-column is followed by the same exact numbers in the other columns for every example table you posted. For example: {11, 26, 41, 56, 71} and {3, 18, 33, 48, 63} are always only present together, and they are exactly 15 numbers apart. Here is a formula that randomly generates numbers for each column BEFORE combining them:

=LET(name, {"B","I","N","G","O"}, 
Gen, LAMBDA(x,TAKE(SORTBY(SEQUENCE(15,,x),RANDARRAY(15)),5)), b, Gen(1),  i, Gen(16),  nn, Gen(31),  g, Gen(46),  o, Gen(61),  n, VSTACK(TAKE(nn, 2), "Free", TAKE(nn, -2)), game, HSTACK(b,i,n,g,o), card, VSTACK(name, game), card )

 

[LogChief]

LAMBDA skills improved, so I thought I would post this updated version. Many thanks to lrobbo314 for the IF formula to add "Free"!

=VSTACK(
    {"B", "I", "N", "G", "O"},
    IF(
        SEQUENCE(5, 5) = 13,
        "Free",
        DROP(
            REDUCE(
                "",
                {1; 16; 31; 46; 61},
                LAMBDA(a, v,
                    HSTACK(a, TAKE(SORTBY(SEQUENCE(15, , v), RANDARRAY(15)), 5))
                )
            ),
            ,
            1
        )
    )
)

 

[Xlambda]

This is a good formula!!
One suggestion though, to not hardcode 1,16,31,....you could have used seq(5,,,15)
............REDUCE(
"",
SEQUENCE(5,,,15),
LAMBDA(a,v,......................

Remembered that I created a SHUFFLE function that I used to help me create large random data sets and I did not use HSTACK or VSTACK because they are too "slow" for big sets.
Maybe if there is interest, I will publish it.
It was fun to apply it for something like bingo.
Here is a glimpse of the functionality

LH that spill.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V
1
2											For BINGO main array will need to shuffle TRANSPOSE(SEQUENCE(5,15)) by column
3						SHUFFLE by column					and TAKE only 5 rows
4		ar				=SHUFFLE(B5:D9,1)
5		1	a	A		2	a	C			=TRANSPOSE(SEQUENCE(5,15))						=SHUFFLE(K6#,1)
6		2	b	B		5	d	B			1	16	31	46	61		1	23	36	55	63
7		3	c	C		3	c	A			2	17	32	47	62		3	27	35	58	61
8		4	d	D		1	b	E			3	18	33	48	63		5	18	43	52	67
9		5	e	E		4	e	D			4	19	34	49	64		10	19	31	47	73
10											5	20	35	50	65		2	30	32	53	70
11						SHUFFLE by row					6	21	36	51	66		4	29	41	50	64
12		ar				=SHUFFLE(B13:D17)					7	22	37	52	67		7	25	45	48	66
13		1	a	A		a	1	A			8	23	38	53	68		11	21	44	57	68
14		2	b	B		b	B	2			9	24	39	54	69		13	22	38	59	62
15		3	c	C		C	c	3			10	25	40	55	70		12	28	42	49	69
16		4	d	D		D	d	4			11	26	41	56	71		14	20	34	46	72
17		5	e	E		E	e	5			12	27	42	57	72		9	26	40	60	75
18											13	28	43	58	73		15	24	33	56	65
19						SHUFFLE by cell					14	29	44	59	74		8	17	39	54	71
20		ar				=SHUFFLE(B21:D25,2)					15	30	45	60	75		6	16	37	51	74
21		1	a	A		5	c	1
22		2	b	B		b	C	B									=TAKE(Q6#,5)
23		3	c	C		e	3	4									1	23	36	55	63
24		4	d	D		d	A	D									3	27	35	58	61
25		5	e	E		E	2	a									5	18	43	52	67
26																	10	19	31	47	73
27																	2	30	32	53	70
28
29											single cell:
30											=TAKE(SHUFFLE(TRANSPOSE(SEQUENCE(5,5)),1),5)
31											3	9	15	17	24
32											5	7	11	16	25
33											1	10	13	18	22
34											4	6	14	19	21
35											2	8	12	20	23
36
Sheet3

Cell Formulas
Range	Formula
F4,K30,Q22,F20,F12,Q5,K5	F4	=FORMULATEXT(F5)
F5:H9	F5	=SHUFFLE(B5:D9,1)
K6:O20	K6	=TRANSPOSE(SEQUENCE(5,15))
Q6:U20	Q6	=SHUFFLE(K6#,1)
F13:H17	F13	=SHUFFLE(B13:D17)
F21:H25	F21	=SHUFFLE(B21:D25,2)
Q23:U27	Q23	=TAKE(Q6#,5)
K31:O35	K31	=TAKE(SHUFFLE(TRANSPOSE(SEQUENCE(5,5)),1),5)
Dynamic array formulas.

 

[lrobbo314]

I looked through the LAMBDA forum and I couldn't find your SHUFFLE formula @Xlambda. Can you post the formula or a link? I'd be interested to see that one.

 

[Xlambda]

Cool, as I said: "Maybe if there is interest, I will publish it."
It must be on a new thread. There is a module group of simple functions interconnected that call each other. So needs a proper presentation.

 

[lrobbo314]

This is something I've come back to a few times. The shuffle by rows and by columns. Seeing this yesterday gave me some motivation. Now I figured it out.

Just curious. You say that VSTACK and HSTACK are 'slow'. The solution I came up with uses TOCOL, TOROW, WRAPCOLS, and WRAPROWS. Are those 'slow' in your opinion? Or am I on the same track as you with this shuffle LAMBDA?