UserForm Textbox

Private Sub CommandButton1_Click()
Dim DiceVals As String, Die1 As Integer, Die2 As Integer, Die3 As Integer, Die4 As Integer
Dim Die5 As Integer, Die6 As Integer

'Roll ye olde dice
Call DiceRoll

'Create an array (of sorts) holding the dice values
DiceVals = "{" & txtDice1 & "," & txtDice2 & "," & txtDice3 & "," & txtDice4 & "," & txtDice5 & "}"

'Determine total of each die
Die1 = Evaluate("SUM(IF(" & DiceVals & "=1,1,0))")
Die2 = Evaluate("SUM(IF(" & DiceVals & "=2,1,0))")
Die3 = Evaluate("SUM(IF(" & DiceVals & "=3,1,0))")
Die4 = Evaluate("SUM(IF(" & DiceVals & "=4,1,0))")
Die5 = Evaluate("SUM(IF(" & DiceVals & "=5,1,0))")
Die6 = Evaluate("SUM(IF(" & DiceVals & "=6,1,0))")

'Total of single values 1 to 6 multiplied by its die number
txtOne = Die1
txtTwo = Die2 * 2
txtThree = Die3 * 3
txtFour = Die4 * 4
txtFive = Die5 * 5
txtSix = Die6 * 6

'Total for 3 of a Kind. If 3 or more dice are the same then total all 5 dice
If Evaluate("MAX(FREQUENCY(" & DiceVals & ",{1,2,3,4,5,6}))") >= 3 Then
txt3ofakind = Evaluate("Sum(" & DiceVals & ")")
Else
txt3ofakind = 0
End If

'Total for 4 of a Kind. If 4 or more dice are the same then total all 5 dice
If Evaluate("MAX(FREQUENCY(" & DiceVals & ",{1,2,3,4,5,6}))") >= 4 Then
txt4ofakind = Evaluate("Sum(" & DiceVals & ")")
Else
txt4ofakind = 0
End If

'Total for a Full House
If Evaluate("MAX(FREQUENCY(" & DiceVals & ",{1,2,3,4,5,6}))") = 3 Then
    If Die1 = 2 Or Die2 = 2 Or Die3 = 2 Or Die4 = 2 Or Die5 = 2 Or Die6 = 2 Then
    txtFullHouse = 25
    Else
    txtFullHouse = 0
    End If
Else
txtFullHouse = 0
End If

'Total of Small Straight. Any 4 dice in sequence. eg 1,2,3,4 or 3,4,5,6 etc
If Die1 > 0 And Die2 > 0 And Die3 > 0 And Die4 > 0 Or _
    Die2 > 0 And Die3 > 0 And Die4 > 0 And Die5 > 0 Or _
    Die3 > 0 And Die4 > 0 And Die5 > 0 And Die6 > 0 Then
txtSmallStraight = 30
Else
txtSmallStraight = 0
End If

'Total of Large Straight. Any 5 dice in sequence. eg 1,2,3,4,5 or 2,3,4,5,6
If Die1 > 0 And Die2 > 0 And Die3 > 0 And Die4 > 0 And Die5 > 0 Or _
    Die2 > 0 And Die3 > 0 And Die4 > 0 And Die5 > 0 And Die6 > 0 Then
txtLargeStraight = 40
Else
txtLargeStraight = 0
End If

'Total for Chance
txtChance = Evaluate("Sum(" & DiceVals & ")")

'Total for Yahtzee
If Evaluate("MAX(FREQUENCY(" & DiceVals & ",{1,2,3,4,5,6}))") = 5 Then
txtYahtzee = 50
Else
txtYahtzee = 0
End If

End Sub


Sub DiceRoll()
'You would need to change this to account for holding dice
txtDice1 = Int(6 * Rnd + 1)
txtDice2 = Int(6 * Rnd + 1)
txtDice3 = Int(6 * Rnd + 1)
txtDice4 = Int(6 * Rnd + 1)
txtDice5 = Int(6 * Rnd + 1)
End Sub