Select directory not file

Option Explicit

'Place the followings in a Userform module

Private Sub UserForm_Initialize()
    Label1.Caption = "" 'Display From directory
    Label2.Caption = "" 'Display To directory
    TextBox1.Text = "" 'Textbox for From extension
    TextBox2.Text = "" 'Textbox for To extension
End Sub

Private Sub CommandButton1_Click()
'a Browse button for From directory
    Label1.Caption = GetFolder
End Sub

Private Sub CommandButton2_Click()
'a Browse button for To directory
    Label2.Caption = GetFolder
End Sub

Private Sub CommandButton3_Click()
'perform this code
    Dim FSO As Object
    Dim GFol As Object
    Dim SF As Object
    Dim F As Object
    Dim i As Long
    Dim pos As Long
    Dim ext As String
    Dim fn As String

    'Check labels and textboxes
    If Label1.Caption = "" Then GoTo Terminate
    If Label2.Caption = "" Then GoTo Terminate
    If Not TextBox1.Text Like ".*" Then GoTo Terminate
    If Not TextBox2.Text Like ".*" Then GoTo Terminate

    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set GFol = FSO.GetFolder(Label1.Caption)

    i = 2
    If GFol.Files.Count > 0 Then
        For Each F In GFol.Files
            pos = InStrRev(F.Path, ".", -1, vbTextCompare)
            ext = Mid(F.Path, pos)
            If ext = TextBox1.Text Then
                pos = InStrRev(F.Name, ".", -1, vbTextCompare)
                fn = Left(F.Name, pos - 1)
                FileCopy F.Path, _
                         Label2.Caption & Application.PathSeparator & _
                         fn & TextBox2.Text
            End If
            i = i + 1
        Next
    End If
    Set FSO = Nothing
    MsgBox "Done"
    Exit Sub
Terminate:
    MsgBox "Please confirm if the inputed information is correct"
End Sub

Private Function GetFolder() As String
'common UDF for getting a folder name
    Dim ff As Object
    Set ff = CreateObject("Shell.Application"). _
             BrowseForFolder(0, "Please select a folder", 0, "c:\\")
    If Not ff Is Nothing Then
        GetFolder = ff.Items.Item.Path
    Else
        GetFolder = vbNullString
    End If
End Function