option buttons - copy/paste cell link problem

Option Explicit

Sub fill_range_with_optionbuttons()
'Erik Van Geit
'050520 0138
Dim rownr As Long, i As Integer
Dim counter As Long
Dim rng As Range
Dim txt() As String
Dim buttoncaption As String
Dim FR As Long, NR As Long, FC As Integer, NC As Integer, SkipRows As Integer

FR = 3
NR = 20
FC = 2
NC = 3

Set rng = Application.InputBox("select the range where you want to put optionbuttons", "SELECT RANGE", Range(Cells(FR, FC), Cells(FR + NR - 1, FC + NC - 1)).Address, Type:=8)
FR = rng(1).Row
FC = rng(1).Column
NR = rng.Rows.Count
NC = rng.Columns.Count

SkipRows = Application.InputBox("how many empty rows do you want between the option buttons?", "SELECT RANGE", 0, Type:=1)

ReDim txt(NC) As String

For i = 1 To NC
txt(i) = InputBox("please provide the caption of the buttons in column " & i, "BUTTON CAPTION", i)
Next i

Application.ScreenUpdating = False

Rows(FR & ":" & FR + NR - 1).RowHeight = 18

For rownr = FR To FR + NR - 1 Step SkipRows + 1
counter = 0
  For i = FC To FC + NC - 1
    counter = counter + 1
    buttoncaption = txt(counter)
    Set rng = Cells(rownr, i)
    If i = FC Then
    ActiveSheet.GroupBoxes.Add(rng.Left, rng.Top, rng.Width * NC, rng.Height).Name = "box" & rownr
    ActiveSheet.Shapes("box" & rownr).OLEFormat.Object.Characters.Text = ""
    End If
    ActiveSheet.OptionButtons.Add(rng.Left, rng.Top, rng.Width, rng.Height).Name = buttoncaption & rownr
    With ActiveSheet.Shapes(buttoncaption & rownr).OLEFormat.Object
    .Characters.Text = buttoncaption
    .LinkedCell = Cells(rownr, FC + NC).Address
    End With
  Next i
Next rownr

Application.ScreenUpdating = False

End Sub