SendInput in VBA

[galileogali]

I need an example of using SendInput in VBA. The Destination window, could be "Notepad" for the sole purpose of facilitating the example. While any example will be accepted and welcomed

 

[Jaafar Tribak]

From AllAPI.net :

The keybd_event function synthesizes a keystroke. The system can use such a synthesized keystroke to generate a WM_KEYUP or WM_KEYDOWN message. The keyboard driver’s interrupt handler calls the keybd_event function.


This is an adaptation from the example provided in AllAPI.net :

Const VK_H = 72
Const VK_E = 69
Const VK_L = 76
Const VK_O = 79
Const KEYEVENTF_KEYUP = &H2
Const INPUT_MOUSE = 0
Const INPUT_KEYBOARD = 1
Const INPUT_HARDWARE = 2

Private Type MOUSEINPUT
  dx As Long
  dy As Long
  mouseData As Long
  dwFlags As Long
  time As Long
  dwExtraInfo As Long
End Type

Private Type KEYBDINPUT
  wVk As Integer
  wScan As Integer
  dwFlags As Long
  time As Long
  dwExtraInfo As Long
End Type

Private Type HARDWAREINPUT
  uMsg As Long
  wParamL As Integer
  wParamH As Integer
End Type

Private Type GENERALINPUT
  dwType As Long
  xi(0 To 23) As Byte
End Type

Private Declare Function SendInput Lib "user32.dll" _
(ByVal nInputs As Long, _
pInputs As GENERALINPUT, _
ByVal cbSize As Long) As Long
 
Private Declare Sub CopyMemory Lib "kernel32" _
Alias "RtlMoveMemory" _
(pDst As Any, _
pSrc As Any, _
ByVal ByteLen As Long)
 
Sub Test()
 
    Shell "NotePad.EXE", 1
 
    'call the SendKey-function
    SendKey VK_H
    SendKey VK_E
    SendKey VK_L
    SendKey VK_L
    SendKey VK_O
 
End Sub
 
Private Sub SendKey(bKey As Byte)
 
    Dim GInput(0 To 1) As GENERALINPUT
    Dim KInput As KEYBDINPUT
    KInput.wVk = bKey  'the key we're going to press
    KInput.dwFlags = 0 'press the key
    'copy the structure into the input array's buffer.
    GInput(0).dwType = INPUT_KEYBOARD   ' keyboard input
    CopyMemory GInput(0).xi(0), KInput, Len(KInput)
    'do the same as above, but for releasing the key
    KInput.wVk = bKey  ' the key we're going to realease
    KInput.dwFlags = KEYEVENTF_KEYUP  ' release the key
    GInput(1).dwType = INPUT_KEYBOARD  ' keyboard input
    CopyMemory GInput(1).xi(0), KInput, Len(KInput)
    'send the input now
    Call SendInput(2, GInput(0), Len(GInput(0)))
    
End Sub

Regards.

 

[galileogali]

Muchas Gracias Jaafar!!!!
se que hablas español y muy bien....
¿o me equivoco?

 

[Jaafar Tribak]

Muchas Gracias Jaafar!!!!
se que hablas español y muy bien....
¿o me equivoco?

De nada galileogali.

Lo hablo un poco . Soy marroqui y el arabe es mi lengua materna pero como vivo en el norte del pays donde aun permanecen muchos espanoles desde la epoca del protectorado y con los cuales tengo una amistad de anos he aprendido a hablar el espanol y me encanta

Y usted de que origen eres ?

Saludos.

 

[galileogali]

Jaafar:
aca agrego una lista de virtual Codes, que me costo bastante encontrar:
http://www.kbdedit.com/manual/low_level_vk_list.html

Pues naci y vivo en Argentina, cerca de Buenos Aires.....

 

[Jaafar Tribak]

Jaafar:
aca agrego una lista de virtual Codes, que me costo bastante encontrar:
http://www.kbdedit.com/manual/low_level_vk_list.html

Pues naci y vivo en Argentina, cerca de Buenos Aires.....

Gracias por la lista y encantado de hacer vuestro conocimiento

Saludos.