ribbon 2007, radio button

[amigos.pl]

Hi there, since there are no radio buttons in 2007 I want to use 2
toggleButtons and use them so one excludes the other one...

I am after the same functionality as you can see in View\Workbook Views\
but I have no idea how this is done

I tried 2 toggleButton in one group, one box and I also tried a separator...didn't work


Can anyone tell me how this is done?


Or (even better) anyone can tell me how to find XML which Excel uses for it's default ribbon?


Thanks in advance


Bartek

 

[JugglerJAF]

Ah, there are radio buttons (or Option Buttons as Excel calls them), they're just very well hidden!

To access them, you need to have the Developer tab visible (which for some bizarre reason - presumably because most users don't need to need to have anything to do with macros or form controls - Excel chooses not to display by default)

1) Click the Office button in top left corner of screen
2) At bottom of dialog, select Excel Options
3) On the Popular sheet tick the box Show Developer Tab on Ribbon (third item down)
4) Click OK to close Options
5) Click the Developer tab on the ribbon
6) Click the Insert icon in the Control group.

You can now add either Forms Controls or ActiveX controls as needed.

 

[amigos.pl]

JugglerJAF, thanks for your help but we are talking about two different things.

I am talking about controls on the ribbon not controls which can be added onto the sheet

http://msdn.microsoft.com/en-us/library/aa338202(office.12).aspx

cheers

Bartek

 

[Andy Pope]

custom ribbon with 2 togglebuttons.
Add getPressed, OnAction and LoadRibbon call backs.

In a standard code module in the workbook add the following code.

Public g_rbxUI As IRibbonUI
Public g_blnToggleA As Boolean
Public g_blnToggleB As Boolean
Public Sub Togglebutton1_onAction(control As IRibbonControl, ByRef cancelDefault)
'
' Code for onAction callback. Ribbon control toggleButton
'
    g_blnToggleA = True
    g_blnToggleB = False
    g_rbxUI.InvalidateControl "Togglebutton1"
    g_rbxUI.InvalidateControl "Togglebutton2"
    
End Sub
Public Sub Togglebutton2_onAction(control As IRibbonControl, ByRef cancelDefault)
'
' Code for onAction callback. Ribbon control toggleButton
'
    g_blnToggleA = False
    g_blnToggleB = True
    g_rbxUI.InvalidateControl "Togglebutton1"
    g_rbxUI.InvalidateControl "Togglebutton2"
    
End Sub

Public Sub Togglebutton1_getPressed(control As IRibbonControl, ByRef returnedVal)
'
' Code for getPressed callback. Ribbon control toggleButton
'
    If control.ID = "Togglebutton1" Then
        returnedVal = g_blnToggleA
    ElseIf control.ID = "Togglebutton2" Then
        returnedVal = g_blnToggleB
    End If
    
End Sub
Public Sub rbxUI_******(ribbon As IRibbonUI)
'
' Code for ****** callback. Ribbon control customUI
'
    Set g_rbxUI = ribbon
End Sub

 

[Andy Pope]

Here is a crude radio button example using the getImage approach.

2 Buttons with OnAction and getImage callbacks. And ****** callback for ribbon.

Code in standard code module within workbook.

Public g_rbxUI As IRibbonUI
Public g_blnOpt(1 To 2) As Boolean
Public Sub Button1_getImage(control As IRibbonControl, ByRef returnedVal)
'
' Code for getImage callback. Ribbon control button
'
    If g_blnOpt(1) Then
        returnedVal = "ActiveXRadioButton"
    Else
        returnedVal = "ShapeDonut"
    End If

End Sub
Public Sub Button2_getImage(control As IRibbonControl, ByRef returnedVal)
'
' Code for getImage callback. Ribbon control button
'
    If g_blnOpt(2) Then
        returnedVal = "ActiveXRadioButton"
    Else
        returnedVal = "ShapeDonut"
    End If
End Sub
Public Sub Button1_onAction(control As IRibbonControl)
'
' Code for onAction callback. Ribbon control button
'
    g_blnOpt(1) = True
    g_blnOpt(2) = False
    g_rbxUI.InvalidateControl "Button1"
    g_rbxUI.InvalidateControl "Button2"
End Sub
Public Sub Button2_onAction(control As IRibbonControl)
'
' Code for onAction callback. Ribbon control button
'
    g_blnOpt(1) = False
    g_blnOpt(2) = True
    g_rbxUI.InvalidateControl "Button1"
    g_rbxUI.InvalidateControl "Button2"

End Sub
Public Sub rbxUI_******(ribbon As IRibbonUI)
'
' Code for ****** callback. Ribbon control customUI
'
    Set g_rbxUI = ribbon
End Sub

 

[amigos.pl]

Thank you Andy, that works perfectly

I can't believe it has to be handled on VBA level isntead of having grouped buttons in XML....Microsoft.

cheers

Bartek

 

[hugoh]

Hi:

I have a problem with this line of code in the macro:

g_rbxUI.InvalidateControl "Togglebutton1"


I get this error---> Runtime Error 91: Object variable or With block variable not set

What may be the reason? I´m using the exact same code as the example from Andy Pope

Kind Regards,

Hugo

 

[RoryA]

It means your ribbon variable has been reset.

 

[hugoh]

It means your ribbon variable has been reset.

Thanks RoryA... Do you know how to fix that? I´m kinda lost here...

Kind Regards,

Hugo