code to be added in existing vba to attach an excel file in emails

I have posted this question in
http://www.excelforum.com/excel-programming/639572-excel-macro-for-sending-emails-2.html#post1959252

Hi,

I have the following code to send automatic email to n number of people at one short.

I have 3 columns in excel.
Column A - Email addres
Column B - Some numbers ( subject)
Column C - Some Links ( body of the message)

wen i run the macro, email goes to all the email address in column A with the subject in column B and with the links in column c respectively and adds the body of the message in sheet 2.

the program is working fine. I just want to add the code to attach an excel file to all these emails.
Assume I have the excel file in My C drive my documents folder.

The code is below


Thanks to leith for providing this code earlier.

'Written: March 31, 2008
'Author: Leith Ross
'Summary: Sends out emails from a worksheet list. The message body is on
' a separate worksheet. This worksheet is copied to a file in
' HTML format. The file is opened an copied as a string which
' becomes the mesaage body in Outlook.

'Used to find the Outlook icon in the system tray. If present then Outlook is running
Private Declare Function FindWindow _
Lib "user32.dll" _
Alias "FindWindowA" _
(ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long

Sub EmailFromWorksheet()

Dim FSO As Object
Dim HTMLcode As String
Dim HTMLfile As Object
Dim Msg As String
Dim myInstance As Boolean
Dim olApp As Object
Dim olEmail As Object
Dim olPID As Long
Dim R As Long
Dim TempFile As String
Dim Wks As Worksheet

'Outlook constants aren't available using late binding
Const olByValue = 1
Const olCC = 2
Const olFolderContacts = 10
Const olMailItem = 0
Const olFormatHTML = 2

'Starting Row of Email Data
R = 2

'Set some program variables
TempFile = "C:\MyEmail.htm"
Set Wks = Worksheets("Body of the Message")

'Start Outlook if it isn't running
If FindWindow("Outlook Notification Area Icon Window", vbNullString) = 0 Then
myInstance = True
olPID = Shell("C:\Program Files\Microsoft Office\Office11\OUTLOOK.exe", 2)
End If

'Assign variable to the running instance
Set olApp = GetObject("", "Outlook.Application")

'Trap any errors
On Error GoTo CleanUp

'Stop the email loop if cell is blank
Do While Cells(R, "A") <> ""

'Add URL to the Body of the Message worksheet
Wks.Cells(1, "A") = Cells(R, "C").Text

'Convert the Message worksheet into HTML
With ActiveWorkbook.PublishObjects.Add( _
SourceType:=xlSourceRange, _
FileName:=TempFile, _
Sheet:=Wks.Name, _
Source:=Wks.UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With

'Read the HTML file back as a string
Set FSO = CreateObject("Scripting.FileSystemObject")
Set HTMLfile = FSO.GetFile(TempFile).OpenAsTextStream(1, -2)
HTMLcode = HTMLfile.ReadAll
HTMLfile.Close
HTMLcode = Replace(HTMLcode, "align=center xublishsource=", _
"align=left xublishsource=")

'Compose the email
Set olEmail = olApp.CreateItem(olMailItem)
With olEmail
.To = Cells(R, "A").Text
.Subject = Cells(R, "B").Text 'Voucher Number
.BodyFormat = olFormatHTML
.HTMLBody = HTMLcode
.Send
End With

'Increment Row counter
R = R + 1
'Delete the tempoary file
Kill TempFile
'Delete the Published Object
With ActiveWorkbook.PublishObjects
.Item(.Count).Delete
End With
'Get the next email cell
Loop

CleanUp:
'Close Outlook instance if this macro created it
If myInstance = True Then TerminateProcess olPID
'Was there an error
If Err <> 0 Then
'Delete the Temp File
If Dir(TempFile) <> "" Then Kill TempFile
'Delete the Publish Object
With ActiveWorkbook.PublishObjects
If .Count <> 0 Then .Item(.Count).Delete
End With
End If

'Free memory resources
Set olApp = Nothing
Set olEmail = Nothing
Set FSO = Nothing

End Sub

Public Sub TerminateProcess(ByVal PID As Long)

Dim colProcessList As Object
Dim objProcess As Object
Dim objServices As Object
Dim ProcessRetVal As Long

'Connect to the WMI namespace through the local computer "."
Set objLocator = CreateObject("WbemScripting.SWbemLocator")
Set objServices = objLocator.ConnectServer(".", "root\cimv2")

' Terminate the Application by its Process ID
Set colProcessList = objServices.ExecQuery _
("SELECT * FROM Win32_Process WHERE ProcessId =" & Str(PID))

' WMI requires a loop even if there is only one object
For Each objProcess In colProcessList
ProcessRetVal = objProcess.Terminate()
If ProcessError(ProcessRetVal) Then Exit For
Next objProcess

CleanUp:
Set objLocator = Nothing
Set objServices = Nothing
Set colProcessList = Nothing
Set objProcess = Nothing
End Sub

Private Function ProcessError(ByVal Err_Value As Long) As Boolean
Dim Msg As String
If Err_Value = 0 Then Exit Function

ProcessError:
Select Case Err_Value
Case 2
Msg = "Access Denied"
Case 3
Msg = "Insufficient Privilege"
Case 8
Msg = "Unknown failure"
Case 9
Msg = "Path Not Found"
Case 21
Msg = "Invalid Parameter"
End Select
MsgBox Msg, vbexcalamtion, "WMI Win32_Process"
ProcessError = True
End Function