Option Explicit
Sub FillOutTemplate()
'Jerry Beaucaire 4/25/2010
'From Sheet1 data fill out template on sheet2 and save
'each sheet as its own file.
Dim LastRw As Long, Rw As Long, Cnt As Long
Dim dSht As Worksheet, tSht As Worksheet
Dim MakeBooks As Boolean, SavePath As String
Application.ScreenUpdating = False 'speed up macro execution
Application.DisplayAlerts = False 'no alerts, default answers used
Set dSht = Sheets("Data") 'sheet with data on it starting in row2
Set tSht = Sheets("Template") 'sheet to copy and fill out
'Option to create separate workbooks
MakeBooks = MsgBox("Create separate workbooks?" & vbLf & vbLf & _
"YES = template will be copied to separate workbooks." & vbLf & _
"NO = template will be copied to sheets within this same workbook", _
vbYesNo + vbQuestion) = vbYes
If MakeBooks Then 'select a folder for the new workbooks
MsgBox "Please select a destination for the new workbooks"
Do
With Application.FileDialog(msoFileDialogFolderPicker)
.AllowMultiSelect = False
.Show
If .SelectedItems.Count > 0 Then 'a folder was chosen
SavePath = .SelectedItems(1) & "\"
Exit Do
Else 'a folder was not chosen
If MsgBox("Do you wish to abort?", _
vbYesNo + vbQuestion) = vbYes Then Exit Sub
End If
End With
Loop
End If
'Determine last row of data then loop through the rows one at a time
LastRw = dSht.Range("A" & Rows.Count).End(xlUp).Row
For Rw = 2 To LastRw
tSht.Copy After:=Worksheets(Worksheets.Count) 'copy the template
With ActiveSheet 'fill out the form
'edit these rows to fill out your form, add more as needed
.Name = dSht.Range("A" & Rw)
.Range("C2") = dSht.Range("A" & Rw)
.Range("F2") = dSht.Range("B" & Rw)
.Range("C6") = dSht.Range("C" & Rw)
.Range("C5") = dSht.Range("D" & Rw)
.Range("B12:E12") = dSht.Range("F" & Rw, "I" & Rw)
.Range("F12:I12") = dSht.Range("K" & Rw, "N" & Rw)
.Range("J12:M12") = dSht.Range("P" & Rw, "S" & Rw)
.Range("B16:E16") = dSht.Range("U" & Rw, "X" & Rw)
.Range("F16") = dSht.Range("Z" & Rw)
.Range("G16:I16") = dSht.Range("AA" & Rw, "AC" & Rw)
.Range("J16:M16") = dSht.Range("AE" & Rw, "AH" & Rw)
.Range("B20:E20") = dSht.Range("AJ" & Rw, "AM" & Rw)
.Range("F20:I20") = dSht.Range("AO" & Rw, "AR" & Rw)
.Range("J20:M20") = dSht.Range("AT" & Rw, "AW" & Rw)
End With
If MakeBooks Then 'if making separate workbooks from filled out form
ActiveSheet.Move
ActiveWorkbook.SaveAs SavePath & Range("B3").Value, xlNormal
ActiveWorkbook.Close False
End If
Cnt = Cnt + 1
Next Rw
dSht.Activate
If MakeBooks Then
MsgBox "Workbooks created: " & Cnt
Else
MsgBox "Worksheets created: " & Cnt
End If
Application.ScreenUpdating = True
End Sub
