Extract data from website in an Excel Spreadsheet

' set references to Microsoft Internet Controls and Microsoft HTML Object Library
' (through Tools>References...)

Option Explicit

Sub example()

Dim page_url As String
Dim myIE As SHDocVw.InternetExplorer
    
Dim i As Long
    
'create new IE instance
Set myIE = New SHDocVw.InternetExplorer
'make IE window visible
myIE.Visible = True
'set page url
page_url = "http://biz.yahoo.com/ic/123/123489.html"
         
'load page
Call LoadWebPage(myIE, page_url)
ie_wait myIE

' overview
With myIE.document.getElementsByTagName("table")
    Cells(2, 2) = .Item(25).innerText ' overview
    
    ' Contact information
    i = 0
    Do Until .Item(i).Rows(0).innerText = "Contact Information"
        i = i + 1
    Loop
    Cells(2, 3) = .Item(i).Rows(1).Cells(1).innerText ' address
    Cells(2, 4) = .Item(i).Rows(2).Cells(1).innerText ' phone
    Cells(2, 5) = .Item(i).Rows(3).Cells(1).innerText ' fax
    
    ' Key people
    i = 0
    Do Until .Item(i).Rows(0).innerText = "Key People "
        i = i + 1
    Loop
    Cells(2, 6) = Mid(.Item(i).Rows(1).Cells(1).innerText, _
                    InStr(1, .Item(i).Rows(1).Cells(1).innerText, ":") + 2) ' Person 1
    Cells(2, 7) = Left(.Item(i).Rows(1).Cells(1).innerText, _
                    InStr(1, .Item(i).Rows(1).Cells(1).innerText, ":") - 1) ' Person 1 position
    Cells(2, 8) = Mid(.Item(i).Rows(2).Cells(1).innerText, _
                    InStr(1, .Item(i).Rows(2).Cells(1).innerText, ":") + 2) ' Person 2
    Cells(2, 9) = Left(.Item(i).Rows(2).Cells(1).innerText, _
                    InStr(1, .Item(i).Rows(2).Cells(1).innerText, ":") - 1) ' Person 2 position
    Cells(2, 10) = Mid(.Item(i).Rows(3).Cells(1).innerText, _
                    InStr(1, .Item(i).Rows(3).Cells(1).innerText, ":") + 2) ' Person 3
    Cells(2, 11) = Left(.Item(i).Rows(3).Cells(1).innerText, _
                    InStr(1, .Item(i).Rows(3).Cells(1).innerText, ":") - 1) ' Person 3 position
End With
        
'clean up
myIE.Quit 'close IE
Set myIE = Nothing
       
End Sub

'load web page
Function LoadWebPage(i_IE As SHDocVw.InternetExplorer, _
                     i_URL As String)
    With i_IE
        .Navigate i_URL 'open page
        Call ie_wait(i_IE) 'wait till it is loaded
    End With
End Function
        
'wait until IE finishes loading the page
Function ie_wait(i_IE As SHDocVw.InternetExplorer)
    Do While i_IE.Busy
        Application.Wait (Now + TimeValue("00:00:01"))
    Loop
End Function