VBA code to open, remove autofilter, save and close multiple files in same directory

Option Explicit

Sub RemoveFilters()

    Const csFilesPattern As String = "*.xls*"
    Dim sFileName As String, _
        sFolderName As String
    Dim iCounter As Integer
    Dim Wbk As Workbook
    Dim Wsh As Worksheet

    '* To start with, use the folder of ThisWorkbook
    sFolderName = Left(ThisWorkbook.FullName, InStrRev(ThisWorkbook.FullName, "\"))
    '* Select folder
    With Application.FileDialog(msoFileDialogFolderPicker)
        .AllowMultiSelect = False
        .Title = "Select a Folder"
        .InitialFileName = sFolderName
        .Show
        If .SelectedItems.Count = 0 Then
            Exit Sub
        Else
            sFolderName = .SelectedItems(1) + "\"
        End If
    End With
    '*
    '* Check if file already exists
    sFileName = Dir(sFolderName + csFilesPattern, vbNormal)
    If sFileName = "" Then
        MsgBox "No Excel files found in the folder " & vbNewLine & sFolderName & vbNewLine & _
            "Please check the folder and try again.", vbCritical, "Files Not Exist"
        Exit Sub
    End If
    '*
    '* Open files and remove filters
    Application.ScreenUpdating = False
    Do While sFileName <> ""
        iCounter = iCounter + 1
        sFileName = sFolderName + sFileName
        Set Wbk = Workbooks.Open(sFileName)
        For Each Wsh In Wbk.Worksheets
            With Wsh
                If .AutoFilterMode Then
                    Wsh.AutoFilterMode = False
                End If
                If Wsh.FilterMode Then
                    Wsh.ShowAllData
                End If
            End With
        Next Wsh
        '*
        '* Save and close the workbook
        Wbk.Save
        Wbk.Close
        sFileName = Dir()
    Loop
    Application.ScreenUpdating = True
    MsgBox "Total files processed: " & iCounter, vbOKOnly, "Statistics"

End Sub