Activating hidden Sheets using If statement.

[AKOsman1]

I have multiple sheets in my project. At the beginning all the sheets are hidden except the "Welcome" Sheet. To continue the user must click the button which will Unhide the next Sheet, "CheckExpiry", I want him to be in and hide the "Welcome " sheet". To continue from the "CheckExpiry" sheet to the next sheet, the user must click the button which will unhide the next Sheet, "Password", I want him to be in and hide the "CheckExpiry" sheet. (and so on and on)
I have created a macro for each button on each sheet. I want to create a single macro to be assigned to all the "continue" buttons on all the sheets using the
"IF..IFELSE..END IF" statement; e.g.

if ActiveSheet = "Welcome" then
"CheckExpiry" = Unhide
"Welcome" = Hide
ElseIf ActiveSheet = "CheckExpiry" then
"Password" = Unhide
"CheckExpiry = Hide
End If

Ps. I have worked on basic Excel spreadsheets for some time but I am absolutely new to VBA. Kindly pardon me for my ignorance.

 

[AKOsman1]

Try the following:

Option Explicit
Sub Hide_Unhide()
    Application.ScreenUpdating = False
    Dim i As Long, j As Long, a
    a = Array("Welcome", "CheckExpiry", "Password") '<-- Put sheet names in the ORDER you want them to open
    i = Application.Match(ActiveSheet.Name, a, 0)
    If i = UBound(a) + 1 Then i = 1 Else i = i + 1
    For j = 1 To Worksheets.Count
        Worksheets(j).Visible = True
    Next j
    For j = 1 To Worksheets.Count
        If j <> i Then Worksheets(j).Visible = False
    Next j
    Application.ScreenUpdating = True
End Sub

Hi Kevin, I sincerely thank you for your help. It is apparent that either way the Sheets must be in order. That being the case I will use your first example.
Once again, many thanks.

 

[kevin9999]

Have a try with the following - shouldn't matter what order the sheets are in in the workbook, they should open in the order you have them in the code:

Option Explicit
Sub Hide_Unhide_V2()
    Application.ScreenUpdating = False
    Dim i As Long, a, sh As String, ws As Worksheet
    a = Array("Welcome", "CheckExpiry", "Password") '<-- Put sheet names in the ORDER you want them to open
    i = Application.Match(ActiveSheet.Name, a, 0)
    If i = UBound(a) + 1 Then i = 1 Else i = i + 1
    sh = a(i - 1)
    For Each ws In Worksheets
        ws.Visible = True
    Next ws
    For Each ws In Worksheets
        If ws.Name <> sh Then ws.Visible = False
    Next ws
    Application.ScreenUpdating = True
End Sub

 

[AKOsman1]

Hi Kevin,
This code works perfectly. I moved the Sheets haphazardly around and still it followed the code sequence. Thanks for you assistance.

 

[kevin9999]

Happy to help, and thanks for the feedback