Conditional Formatting or Counting if within "x" of another value

[mbpaul1987]

I have a rather interesting situation that I can't seem to find an easy solution to. I have a few workbooks that have 3000+ lines of data in them. I need to find a way to pull a count of items that are within a certain distance of other items. As a very simplified example I will use the following table:

Item	Location (mile)
I	1
S	3
B	3.5
I	4
I	8
S	9
I	20
B	21
I	22
I	24
S	26

<tbody>
</tbody>

I need to find a way to to count the number of "I" that are within "2 miles" (this number will be variable) of an S. In the case of the example there are 4. My Initial thought was to try to find a way to conditionally format the "I" rows that meet that criteria then I can easily sort them and count them. However, Ultimately I am just looking for an overall count of items within a set distance from another Item.

Item	Location (mile)
I	1
S	3
B	3.5
I	4
I	8
S	9
I	20
B	21
I	22
I	24
S	26

<tbody>
</tbody>

Thanks for any Help

Michael

 

[Marcelo Branco]

Maybe something like this

	A​	B​	C​	D​	E​
1​	Item​	Location (mile)​		Distance​	Result​
2​	I​	1​		2​	4​
3​	S​	3​		4​	5​
4​	B​	3,5​
5​	I​	4​
6​	I​	8​
7​	S​	9​
8​	I​	20​
9​	B​	21​
10​	I​	22​
11​	I​	24​
12​	S​	26​

Distances in D2, D3...

Array formula in E2 copied down
=SUM(IF(IF(A$2:A$12="I",IF(ISNUMBER(TRANSPOSE(IF(A$2:A$12="S",B$2:B$12))),ABS(B$2:B$12-TRANSPOSE(B$2:B$12))))<=D2,1))
confirmed with Ctrl+Shift+Enter, not just Enter

Hope this helps

M.

 

[Marcelo Branco]

A little simpler formula

E2 copied down
=SUM(IF(IF(A$2:A$12="I",ABS(B$2:B$12-TRANSPOSE(IF(A$2:A$12="S",B$2:B$12,9.99E+307))))<=D2,1))
Ctrl+Shift+Enter

M.

 

[mbpaul1987]

Maybe something like this

	A​	B​	C​	D​	E​
1​	Item​	Location (mile)​		Distance​	Result​
2​	I​	1​		2​	4​
3​	S​	3​		4​	5​
4​	B​	3,5​
5​	I​	4​
6​	I​	8​
7​	S​	9​
8​	I​	20​
9​	B​	21​
10​	I​	22​
11​	I​	24​
12​	S​	26​

<tbody>
</tbody>

Distances in D2, D3...

Array formula in E2 copied down
=SUM(IF(IF(A$2:A$12="I",IF(ISNUMBER(TRANSPOSE(IF(A$2:A$12="S",B$2:B$12))),ABS(B$2:B$12-TRANSPOSE(B$2:B$12))))<=D2,1))
confirmed with Ctrl+Shift+Enter, not just Enter

Hope this helps

M.

Hi Marcelo,

Thanks for the reply! The solution works great for the small distances but now the issue that I'm having is when I get into longer distances that might overlap it may count the instance twice:

Item	Location (mile)		Distance	Result
I	1		2	4
S	3		4	5
B	3.5		6	8
I	4
I	8
S	9
I	20
B	21
I	22
I	24
S	26

<colgroup><col width="64" span="5" style="width:48pt"> </colgroup><tbody>
</tbody>

 

[mbpaul1987]

Sorry this was a duplicate post. see above

 

[Marcelo Branco]

This is because some rows are being counted twice. For example, the distances from row5 (=4) to row3 (=3) and to row7(=9) are less or equal the value in D4(=6). If you do not want such double counting we need an alternative formula, that is:

E2 copied down
=SUM(--(MMULT(--(IF(A$2:A$12="I",ABS(B$2:B$12-TRANSPOSE(IF(A$2:A$12="S",B$2:B$12,9.99E+307))),9.99E+307)<=D2),ROW(A$2:A$12)^0)>0))
Ctrl+Shift+Enter

	A​	B​	C​	D​	E​
1​	Item​	Location (mile)​		Distance​	Result​
2​	I​	1​		2​	4​
3​	S​	3​		4​	5​
4​	B​	3,5​		6​	6​
5​	I​	4​
6​	I​	8​
7​	S​	9​
8​	I​	20​
9​	B​	21​
10​	I​	22​
11​	I​	24​
12​	S​	26​

<tbody>
</tbody>

M.

 

[mbpaul1987]

This is because some rows are being counted twice. For example, the distances from row5 (=4) to row3 (=3) and to row7(=9) are less or equal the value in D4(=6). If you do not want such double counting we need an alternative formula, that is:

E2 copied down
=SUM(--(MMULT(--(IF(A$2:A$12="I",ABS(B$2:B$12-TRANSPOSE(IF(A$2:A$12="S",B$2:B$12,9.99E+307))),9.99E+307)<=D2),ROW(A$2:A$12)^0)>0))
Ctrl+Shift+Enter

	A​	B​	C​	D​	E​
1​	Item​	Location (mile)​		Distance​	Result​
2​	I​	1​		2​	4​
3​	S​	3​		4​	5​
4​	B​	3,5​		6​	6​
5​	I​	4​
6​	I​	8​
7​	S​	9​
8​	I​	20​
9​	B​	21​
10​	I​	22​
11​	I​	24​
12​	S​	26​

<tbody>
</tbody>

M.

Hi Marcelo,

That works perfectly. Thank you so much!! I must admit that array formulas are just not something that I have been able to fully wrap my head around and so to me they are about equivalent to magic . Once I'm done my current project I'm looking forward to doing a bit of research to properly understand how your formula works.

Again thanks so much!!

Michael

 

[Marcelo Branco]

Hi Michael,

You are welcome. Glad to help

M.