Creating a Game in Excel...Have a Range & If statement question

[mike30549]

I have several Sheets involved but I'll have Sheet 2 Active. When I'm on "Sheet 2" I need to know when cell ("C14") becomes active with an IF statement I'm guessing. Once it becomes active, I then need to know if the string in cell ("B2") on Sheet 1 = "Fighter" then I want to insert "some wording regarding the fighter here" in cell ("C14") on Sheet 2. IF it's not "Fighter"then is it "Mage"? If so then insert "some wording regarding the mage here".

This is short hand for example.

if cell C14 on Sheet 2 is active then
check cell B2 on Sheet1, is text = "Fighter"? Then
"You are brave and use a sword"
if Else is cell B2 on Sheet1 = "Mage"? Then
"You cast spells"
etc..

I need to know how to code this in VBA. I've spent hours searching and trying various code but can't get it right. Thanks ahead of time.

 

[Jerry Sullivan]

Hi and Welcome to MrExcel,

You can do that with an Event procedure.

Copy the code below into the Sheet Code Module of Sheet 2.
(Right-Click on the sheet tab for Sheet 2 > View code to get to that module)

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

 Dim sText As String
  
 If Target.Address = "$C$14" Then
   Select Case Sheets("Sheet 1").Range("B2").Value
      Case "Fighter"
         sText = "You are brave and use a sword"
      Case "Mage"
         sText = "You cast spells"
      Case Else
         'clear any previous value in C14
         sText = ""
   End Select
   Application.EnableEvents = False
   Me.Range("C14").Value = sText
   Application.EnableEvents = True
 End If
End Sub

Check that your actual sheet name matches the name in the code ("Sheet 1" vs "Sheet1")

 

[mike30549]

Jerry, it's works like a charm. Thank you very much!