Excel VBA navigating to hyperlink that downloads file and saving file

[heavican03]

I have a vba macro that is navigating to a hyperlink and downloading a file that is then saved. The only problem I am having with it is I can't get it to stop bringing up the Microsoft office warning that the file might contain harmful files. Can you help?

Sub LinkAndCopy()
     
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
     
     
    ThisWorkbook.FollowHyperlink Address:="http://cts/Tacs/LDCOperationDrillExport/762"
     
    ActiveWorkbook.SaveAs "C:\Users\q6bxh0\Documents\downloads\file.xlsx"
     ActiveWorkbook.Close
     
     
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
     
     
End Sub

 

[Fishboy]

I have a vba macro that is navigating to a hyperlink and downloading a file that is then saved. The only problem I am having with it is I can't get it to stop bringing up the Microsoft office warning that the file might contain harmful files. Can you help?

Sub LinkAndCopy()
     
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
     
     
    ThisWorkbook.FollowHyperlink Address:="http://cts/Tacs/LDCOperationDrillExport/762"
     
    ActiveWorkbook.SaveAs "C:\Users\q6bxh0\Documents\downloads\file.xlsx"
     ActiveWorkbook.Close
     
     
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
     
     
End Sub

Hi heavican03, welcome to the boards.

Here is the code I used for downloading from a URL which I have tweaked to suit your example above. This code has no popup warnings beyond my own custom "File Downloaded" message to confirm the action was completed, but this can simply be deleted from the end.

Sub Download_CSV()
Application.ScreenUpdating = False
    Dim myURL As String
    myURL = "http://cts/Tacs/LDCOperationDrillExport/762"
    
    Dim WinHttpReq As Object
    Set WinHttpReq = CreateObject("Microsoft.XMLHTTP")
    WinHttpReq.Open "GET", myURL, False
    WinHttpReq.Send
    
    myURL = WinHttpReq.ResponseBody
    If WinHttpReq.Status = 200 Then
        Set oStream = CreateObject("ADODB.Stream")
        oStream.Open
        oStream.Type = 1
        oStream.Write WinHttpReq.ResponseBody
        oStream.SaveToFile ("C:\Users\q6bxh0\Documents\downloads\file.xlsx"), 2
        oStream.Close
    End If
    MsgBox "File Downloaded"
End Sub