Extract strings from cell and copy to rows below

[Vlada]

Dear experts,

If someone could help with problem i have, would be highly appreciated!

On picture1, column G, contains strings separated with ; that each, one by one, needs to be copied in rows below.
Number of rows is defined in column H.

Hope my question is clear, and the result needed is shown in Picture2.

Thanks in advance!

 

[Rhodie72]

Below what? Before where? Below where?

Complete the question then maybe I can answer.

 

[Peter_SSs]

Welcome to the MrExcel board!

See if this does what you want.
Test with a copy of your data.

Sub AdjustRows()
  Dim a As Variant, bits As Variant
  Dim i As Long, j As Long
  
  With Range("G2", Range("H" & Rows.Count).End(xlUp))
    a = .Value
    i = 1
    Do Until i > UBound(a)
      If a(i, 2) > 1 Then
        bits = Split(a(i, 1), ";")
        For j = 0 To UBound(bits)
          a(i + j, 1) = bits(j)
        Next j
      End If
      i = i + a(i, 2)
    Loop
    .Value = a
  End With
End Sub

Before:

Vlada.xlsm
	A	B	C	D	E	F	G	H
1	ata	As	Rt	TY	UI	Yt	FV	NR
2	a	b	v	c	x	t	asd;sdr;erty	3
3	a	b	v	c	x	t	asd;sdr;erty	3
4	a	b	v	c	x	t	asd;sdr;erty	3
5	a	b	v	c	x	u	asd;sdr	2
6	a	b	v	c	x	u	asd;sdr	2
7	a	b	v	c	x	u	asd	1
Sheet1

After:

Vlada.xlsm
	A	B	C	D	E	F	G	H
1	ata	As	Rt	TY	UI	Yt	FV	NR
2	a	b	v	c	x	t	asd	3
3	a	b	v	c	x	t	sdr	3
4	a	b	v	c	x	t	erty	3
5	a	b	v	c	x	u	asd	2
6	a	b	v	c	x	u	sdr	2
7	a	b	v	c	x	u	asd	1
Sheet1

 

[Vlada]

Hi Peter,

Thanks for welcome, I am happy to join this community of excel masters .

The solution works PERFECTLY, it is exactly what i need!

Thank you countless times for your precious support!

 

[Peter_SSs]

You are very welcome. Thanks for the follow-up.