Find and Replace VBA from a list in a 2nd sheet

[Nineball]

I have looked through a lot of threads but can't find (or understand) what I'm looking for. I have a sheet that has a column of text sentences. I want to find specific text in each row and replace the text with another value from a 2nd worksheet. In the 2nd worksheet, column a has the text to find and column b has the replacement text which in most if not all cases a null value. I have hundreds of replacement rows so an array isn't practical.

I have uploaded an example of what I'm trying to do. The example1 sheet has a column of text I want to search through. When it finds a value from the lookup sheet in column a, I want it to replace the text with the value from the lookup sheet in column b. I hope this is clear.
thanks

 

[Domenic]

The following macro assume that the workbook running the code contains both worksheets...

Sub FindAndReplace()

    Dim sentencesWorksheet As Worksheet
    Dim searchRange As Range
    Dim replaceTable As Variant
    Dim findWhat As String
    Dim replaceWith As String
    Dim i As Long
    
    Set sentencesWorksheet = ThisWorkbook.Worksheets("Sentences")
    
    With sentencesWorksheet
        Set searchRange = .Range("B2:B" & .Cells(.Rows.Count, "B").End(xlUp).Row)
    End With
        
    With ThisWorkbook.Worksheets("F and R")
        replaceTable = .Range("A2:B" & .Cells(.Rows.Count, "A").End(xlUp).Row).Value
    End With
    
    For i = 1 To UBound(replaceTable)
        findWhat = replaceTable(i, 1)
        replaceWith = replaceTable(i, 2)
        searchRange.Replace _
            what:=findWhat, _
            replacement:=replaceWith, _
            lookat:=xlPart, _
            MatchCase:=False
    Next i
    
End Sub

Hope this helps!

 

[Nineball]

Thank you for the quick response. You've saved me a lot of work. Much appreciated

 

[Domenic]

That's great, I'm glad I could help.

Cheers!