How to get GMT time on MAC with vba.

[MoshiM]

Currently using the following on Windows to get GMT/UTC time but I need a way of doing this on MAC as well. Thanks in advance.

Function UTC() As Date

Dim dt As Object

Set dt = CreateObject("WbemScripting.SWbemDateTime")
    
With dt
    .SetVarDate Now
    UTC = .GetVarDate(False)
End With
    'Debug.Print UTC
End Function

 

[Tetra201]

Here is what I have for Mac Excel 2011:

Private Declare Function popen Lib "libc.dylib" (ByVal command As String, ByVal mode As String) As Long
Private Declare Function fread Lib "libc.dylib" (ByVal outStr As String, ByVal size As Long, ByVal items As Long, ByVal stream As Long) As Long
Private Declare Function feof Lib "libc.dylib" (ByVal file As Long) As Long
Function UTC() As Date
    Dim f As Long, s As String, r As Long, x As String
    f = popen("date -u +%T", "r")
    If f = 0 Then Exit Function
    While feof(f) = 0
        s = Space(50)
        r = fread(s, 1, Len(s) - 1, f)
        If r > 0 Then
            s = Left$(s, r)
            x = x & s
        End If
    Wend
    UTC = CDate(x)
End Function

 

[MoshiM]

Here is what I have for Mac Excel 2011:

Thank you for your response. Unfortunately I have no way of testing it until Thursday.

If the user isn't on Excel 2011 would the following conditional compilers in the code below be correct?

The following link shows that ptrsafe is needed for MAC excel 2016 but not 2011. VBA - Mac APIs | vba Tutorial
What about older versions ?

 #If VBA7 Then

        Private Declare PtrSafe Function popen Lib "libc.dylib" (ByVal command As String, ByVal mode As String) As LongPtr
        Private Declare PtrSafe Function pclose Lib "libc.dylib" (ByVal file As LongPtr) As Long
        Private Declare PtrSafe Function fread Lib "libc.dylib" (ByVal outStr As String, ByVal size As LongPtr, ByVal items As LongPtr, ByVal stream As LongPtr) As Long
        Private Declare PtrSafe Function feof Lib "libc.dylib" (ByVal file As LongPtr) As LongPtr

 #Else
        Private Declare Function popen Lib "libc.dylib" (ByVal command As String, ByVal mode As String) As Long
        Private Declare Function fread Lib "libc.dylib" (ByVal outStr As String, ByVal size As Long, ByVal items As Long, ByVal stream As Long) As Long
        Private Declare Function feof Lib "libc.dylib" (ByVal file As Long) As Long
 #End If

 

[Tetra201]

This might work; unfortunately, I have no means of testing it.