How to pass values from one sheet to another sheet if condition met?

[Rampage598]

This is my scenario

I want to pass the values from sheet2 to sheet1 according to ID...in here from sheet2 id= 1 data=a will go into the sheet1 id=1 data column....
This is my expected output

Is there any possible way to do this in excel using macros?
Can anyone help me with this?

 

[airforceone]

kindly try below code (My working code from another thread I'm working on...)
also, you may want to search first for other thread post here for a similar problem

Sub A_PROB104_MREXCEL_Rampage598()

    Dim Row4Sheet2 As Integer, LRow As Long, iCTR As Integer, WSCopy As Worksheet
    Set WSCopy = ActiveSheet
    ActiveSheet.Select
    'Count Row even with Empty Cells
    LRow = ActiveSheet.UsedRange.rows.Count + ActiveSheet.UsedRange.rows(1).Row

    iCTR = 2
    Row4Sheet2 = 2
    Do While iCTR < LRow
        If Not IsEmpty(Cells(iCTR, 2)) Then
            WSCopy.Range("A" & iCTR & ":B" & iCTR).Copy Worksheets("PAGE02").Range("A" & Row4Sheet2)
            Row4Sheet2 = Row4Sheet2 + 1
        End If
        iCTR = iCTR + 1
    Loop

End Sub

 

[mumps]

Try:

Sub CompareID()
    Application.ScreenUpdating = False
    Dim i As Long, srcWS As Worksheet, desWS As Worksheet, v1 As Variant, v2 As Variant, dic As Object
    Set srcWS = Sheets("Sheet2")
    Set desWS = Sheets("Sheet1")
    v1 = srcWS.Range("A2", srcWS.Range("A" & Rows.Count).End(xlUp)).Resize(, 2).Value
    v2 = desWS.Range("A2", desWS.Range("A" & Rows.Count).End(xlUp)).Value
    Set dic = CreateObject("Scripting.Dictionary")
    For i = LBound(v1) To UBound(v1)
        If Not dic.exists(v1(i, 1)) Then
            dic.Add v1(i, 1), v1(i, 2)
        End If
    Next i
    For i = LBound(v2) To UBound(v2)
        If dic.exists(v2(i, 1)) Then
            desWS.Range("B" & i + 1) = dic(v2(i, 1))
        End If
    Next i
    Application.ScreenUpdating = True
End Sub