Macro for making a backup of multiple ranges

[Hoeye]

Dear experts,

I'm developing sort of a year-planner/invoice-maker. This is a work in progress, but it's working and as of 1-1-2010 it's in use! My collegue filled the year.

Now I'm working on the workbook. Changing this, and that, modifying macros. Now I'm looking for this:

I want my collegue to be able to press a backup button > this backs up about 20 ranges on every one of 15 worksheets. A file must be created "backup -date-<DATE>.xlsx" or something similar. Backing up the whole workbook is easy, but I don't know how to back up only the needed ranges.

Now I take this backup file, and press a restore (or import) button, and the macro takes this backupfile and imports the data.

I searched the forum, googled the internet, but I haven't seen a solution.

Can someone point me in the right direction?

 

[Legacy 98055]

This is the fastest and easiest way to back up large ranges that I know of. The example backs up a range named "MyBackUpRange" and then clears the contents of the same. It then restores the range. Name a large range using the name above to test...

Sub Example()
    BackUpRange "MyBackUpRange"
    Range("MyBackUpRange").ClearContents
    MsgBox "Contents Cleared.  Will now restore."
    RestoreRange "MyBackUpRange"
End Sub

Sub BackUpRange(SourceName As String)
    Dim Data, FileNum As Integer

    Data = Range(SourceName)
    FileNum = FreeFile
    Open ThisWorkbook.Path & "\" & SourceName & ".dat" For Binary As #FileNum
        Put #FileNum, 1, Data
    Close #FileNum
End Sub

Sub RestoreRange(TargetName As String)
    Dim Data, FileNum As Integer

    FileNum = FreeFile
    Open ThisWorkbook.Path & "\" & TargetName & ".dat" For Binary As #FileNum
        Get #FileNum, 1, Data
    Close #FileNum
    Range(TargetName) = Data
End Sub

 

[Hoeye]

Thx,

I'm going to try this...