Need VBA code to print specific pages or all pages in a MultiPage UserForm

[pimp_mentality]

Good day all,

As the topic suggested I would like a line of code which will allow me to print a specific page from a multipage UserForm or print the entire form (all pages) when click commandbutton I created

Assistance in this regard would be greatly appreciated.

I would also like a line of code which will clear all textboxes when I click the commandbutton I created.

Thanks

 

[pbornemeier]

Add a listbox to the non-tab area which will be used to select pages to print with multiselect set to frmMultiSelectExtended
Add a command button to the non-tab area which will be used to print selected pages
Add the following code to the form code page, update control names in code to match yours

Option Explicit
Private Sub CommandButton1_Click()
    PrintSpecifiedFormTabs
End Sub

Private Sub UserForm_Activate()
    'PopulateListBox
    
    Dim lTabCount As Long
    Dim lIndex As Long
    
    lTabCount = Me.MultiPage1.Pages.Count
    For lIndex = 1 To lTabCount
        Me.ListBox1.AddItem lIndex
    Next
    
End Sub

Sub PrintSpecifiedFormTabs()

    Dim strThisWorkbook As String
    Dim lTabIndex As Long
    Dim iAnswer As VbMsgBoxResult
    Dim lPrintCount As Long

    strThisWorkbook = ActiveWorkbook.Name
    
    'How Many Selected?
    For lTabIndex = 0 To Me.ListBox1.ListCount - 1
        If Me.ListBox1.Selected(lTabIndex) Then
            lPrintCount = lPrintCount + 1
        End If
    Next
    
    If lPrintCount > 0 Then
        iAnswer = MsgBox("You have selected " & lPrintCount & " page" & _
            IIf(lPrintCount > 1, "s", "") & " to print." & vbLf & vbLf & _
            "Do you wish to continue?", vbYesNo, "Print Selected Page " & _
            IIf(lPrintCount > 1, "s", "") & "?")
        If iAnswer = vbYes Then
            For lTabIndex = 0 To UserForm1.ListBox1.ListCount - 1
                If UserForm1.ListBox1.Selected(lTabIndex) Then
                    Me.MultiPage1.Value = lTabIndex
                    'Debug.Print "print tab " & lTabIndex
                    Me.PrintForm
                End If
            Next
            
            'Deselect tabs
            For lTabIndex = 0 To Me.ListBox1.ListCount - 1
                If Me.ListBox1.Selected(lTabIndex) Then
                    Me.ListBox1.Selected(lTabIndex) = False
                End If
            Next
            
            MsgBox lPrintCount & " page" & IIf(lPrintCount > 1, "s", "") & _
                " sent to printer", vbInformation, "User Cancelled Printing"
        Else
            MsgBox "Printing Cancelled", vbExclamation, "User Cancelled Printing"
        End If
    End If
    
End Sub