Sorting table gives error

[eirikdaude]

I'm having a bit of trouble with sorting a table using VBA. The macro I'm using is this

Private Sub test()
    Dim lo As ListObject
    
    Set lo = HCP_justering.ListObjects(1)
    
    lo.AutoFilter.ShowAllData
    
    With lo.Sort
        .SortFields.Clear
        .SortFields.Add _
            Key:=lo.ListColumn(1).Range, _
            SortOn:=xlSortOnValues, _
            Order:=xlAscending, _
            DataOption:=xlSortNormal
        .Header = xlYes
        .MatchCase = True
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End Sub

However I get an error on the line ".SortFields.Add (...)" saying "Runtime error 438. Object doesn't support this property or method".

Can someone give me a pointer to where I'm going wrong?

 

[Fluff]

It should be ListColumns(1), your missing the s

 

[eirikdaude]

Ugh, after having struggled with this for ages, I of course see the problem five minutes after posting here. It should be

Key:=lo.ListColumns(1).Range, _

not

Key:=lo.ListColumn(1).Range, _

 

[JEC]

Try sorting like this

Sub jec()
  With Sheets(1).ListObjects(1).DataBodyRange
    .Sort .Cells(1, 1), 1, , , , , , 1
  End With
End Sub

 

[Fluff]

Glad you sorted it & thanks for the feedback.