Transpose single column into multiple rows based on criteria

[farisi]

Hi,
I would like to transpose a single column into multiple rows based on 2 criteria:
1. If "name" change the letter, it will create new row
2. If each "name" have more than 5 "node", it will create new row

Input:

Output:

Any help/advice will be very appreciated. Thanks

 

[DanteAmor]

Hello @farisi
Welcome to the MrExcel forum. Please accept my warmest greetings and sincere hope that all is well.

Try this macro:

Sub TransposeColumn()
  Dim i As Long, j As Long
  Dim c As Range, f As Range
  Range("D:J").ClearContents
  For Each c In Range("A2", Range("A" & Rows.Count).End(3))
    Set f = Range("D:D").Find(c.Value, , xlValues, xlWhole, xlByRows, xlPrevious)
    If f Is Nothing Then
      Range("D" & Rows.Count).End(3)(2).Resize(1, 2).Value = c.Resize(1, 2).Value
    Else
      j = Cells(f.Row, Columns.Count).End(1).Column
      If j = Columns("I").Column Then
        Range("D" & Rows.Count).End(3)(2).Resize(1, 2).Value = c.Resize(1, 2).Value
      Else
        Cells(f.Row, j + 1).Value = c.Offset(0, 1).Value
      End If
    End If
  Next
End Sub

The results as shown in the image below.

Dante Amor
	A	B	C	D	E	F	G	H	I
1	Name	Node		Name	Node	Node	Node	Node	Node
2	A	1		A	1	2	3	4	5
3	A	2		A	6	7
4	A	3		B	8	9	10	11	12
5	A	4		B	13	14
6	A	5		C	15	16	17
7	A	6
8	A	7
9	B	8
10	B	9
11	B	10
12	B	11
13	B	12
14	B	13
15	B	14
16	C	15
17	C	16
18	C	17
Hoja2

HOW TO INSTALL MACROs
------------------------------------
If you are new to macros, they are easy to install and use. To install it, simply press ALT+F11 to go into the VB editor and, once there, click Insert/Module on its menu bar, then copy/paste the above code into the code window that just opened up. That's it.... you are done. To use the macro, go back to the worksheet with your data on it and press ALT+F8, select the macro name (FixAndSplitApartRecords) from the list that appears and click the Run button. The macro will execute and perform the action(s) you asked for. If you will need to do this again in this same workbook, and if you are using XL2007 or above, make sure you save your file as an "Excel Macro-Enabled Workbook (*.xlsm) and answer the "do you want to enable macros" question as "Yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

--------------
Let me know the result and I'll get back to you as soon as I can.
Cordially
Dante Amor
--------------​

 

[farisi]

Hi, thank you so much for your warmth welcome and your solution, it works like a charm.
I really appreciate it, thanks man....