Vba code to generate a list of numbers in random order

[JOAO12]

Searching this forum, I found the below code to generate a list of numbers in random order using vba.

I'm trying to adapt this code in order to add a new variable (x), so that the upperbound value of array V is the value of this variable (x).

Sub Demo1()
    Dim x, V, L&, R&, S
        x = 132
        V = [ROW(101:x)]
    For L = UBound(V) To 2 Step -1
        R = Application.RandBetween(1, L)
        S = V(L, 1):  V(L, 1) = V(R, 1):  V(R, 1) = S
    Next
        [A1].Resize(UBound(V)).Value2 = V
End Sub

How could I rewrite this piece of code?

        V = [ROW(101:x)]

 

[lrobbo314]

How about this?

V = Evaluate("TRANSPOSE(INDEX(ROW(101:" & x & "),))")

 

[Fluff]

Another option

        V = Evaluate("ROW(101:" & x & ")")

 

[JOAO12]

I would like to thank you both, Fluff and Irobbo314. Fluff's answer works fine.

Irobbo314's answer also works, but the use of "transpose" creates the need to change the code as shown below.

Sub Demo1()
    Dim x, V, L&, R&, S
        x = 132
        V = Evaluate("TRANSPOSE(INDEX(ROW(101:" & x & "),))")
    For L = UBound(V) To 2 Step -1
        R = Application.RandBetween(1, L)
        S = V(L):  V(L) = V(R):  V(R) = S
    Next
        [A1].Resize(UBound(V)).Value2 = Application.Transpose(V)
End Sub

 

[Fluff]

Glad we could help & thanks for the feedback.