What "type" should olMailItem be?

[squidgeny]

Hi all,

I can make the below subroutine work if I declare olMailItem as Variant. But, as I understand it (and my understanding is somewhat limited - I'm new to VBA), Variant is a sort of wildcard. Can anyone tell me what it specifically should be?

I've tried Outlook.MailItem but that gives me a "User-defined type not defined" error.

Option Explicit
Sub testEmail()

    Dim myOutlook As Object
    Dim myMailItem As Object
    
    Set myOutlook = CreateObject("Outlook.Application")
    
    Set myMailItem = myOutlook.CreateItem(olMailItem)

    myMailItem.Display

    Set myMailItem = Nothing
    Set myOutlook = Nothing
    
End Sub

 

[Andrew Poulsom]

You can use OutLook.MailItem if you have set a reference to Outlook (early binding). Otherwise it's Object.

 

[ZVI]

Hi,
olMailItem is the Outlook's constant equal to zero.
Without reference (VBE-Tools-References) to Outlook define this constant in Excel explicitly.

Option Explicit
Sub TestEmail()

    ' olMailItem is the Outlook Application's constant,
    ' therefore define it here (in Excel) explicitly
    Const olMailItem As Long = 0
    
    Dim myOutlook As Object
    Dim myMailItem As Object
    
    ' Try using of already open Outlook Application
    On Error Resume Next
    Set myOutlook = GetObject(, "Outlook.Application")
    
    ' If Outlook Application was not active then create it
    If Err Then Set myOutlook = CreateObject("Outlook.Application")
    On Error GoTo 0
    
    Set myMailItem = myOutlook.CreateItem(olMailItem)

    myMailItem.Display

    Set myMailItem = Nothing
    Set myOutlook = Nothing
    
End Sub

 

[squidgeny]

Interesting! Thanks

And thank you for the error code... that will be useful