4th Wednesday of each month

[lex_m]

This will be use with Excel 2003

I have the date that is the 4th Wednesday of the month, lets say 11-23-2022 in cell A2 what formula can I put in A3 and copy it down to get the 4th Wednesday of each month?
So the results would be
A3 12-28-22
A4 1-25-23
A5 2-22-23
A6 3-22-23
A7 4-26-23
On down the row
Thanks

 

[Legacy 143009]

0 represents the place of Wednesday in order of weekdays. 4 is for 4th Wednesday.

=WORKDAY.INTL(DATE("2022",D1,0),$E$1,"1101111")

 

[Fluff]

Workday.intl didn't come in until 2010 & so won't work for the OP.

 

[Fluff]

How about

Fluff.xlsm
	A	B
1
2	23/11/2022
3	28/12/2022	28/12/2022
4	25/01/2023	25/01/2023
5	22/02/2023	22/02/2023
6	22/03/2023	22/03/2023
7	26/04/2023	26/04/2023
8	24/05/2023	24/05/2023
9	28/06/2023	28/06/2023
10	26/07/2023	26/07/2023
11	23/08/2023	23/08/2023
Data

Cell Formulas
Range	Formula
A3:A11	A3	=DATE(YEAR(A2),MONTH(A2)+1,29)-WEEKDAY(DATE(YEAR(A2),MONTH(A2)+1,4))
B3	B3	=WORKDAY.INTL(EOMONTH(A2,0),4,"1101111")
B4:B11	B4	=WORKDAY.INTL(EOMONTH(B3,0),4,"1101111")

Use the formula in col A. Col B will only work with xl2010 or newer.

 

[lex_m]

Thanks Fluff that works great!

​

 

[Fluff]

Glad we could help & thanks for the feedback.