Ayuda formula matricial

[asnieto]

Hola de nuevo.
Por favor podrian ayudarme.
En una lista tengo tipode documento en A numero de documento en B y edad en I,
Algunas edades deben estimarse por el documento de identidad.
Tengo la siguiente formula que deberia hacerlo, pero no logro que funcione, si coloco solo la condicion dos del Y funciona pero involucra todos los "tipos de documentos" y necesito que compare CC con, CC TI con TI
=REDONDEAR(PROMEDIO(SI(Y(IZQUIERDA(B5336,2)=IZQUIERDA($B$5681:B24784,2),(IZQUIERDA(A5336,2)=IZQUIERDA($A$5681:A24784,2))),$I$5681:I24784,"")),0)

esta funciona bien
=REDONDEAR(PROMEDIO(SI(IZQUIERDA(B5336,2)=IZQUIERDA($B$5681:B24784,2),$I$5681:I24784,"")),0)

Me pueden orientar por favor.
gracias.

 

[paliman]

Hola.
¿Podrás mandar unas diez o quince filas de tu planilla? No me puedo dar cuenta bien de qué se trata.

De todos modos, creo haber visto por ahí que la función "Y" no se lleva bien con las fórmulas matriciales. Pero mandame unas cuantas líneas y vamos a ver qué podemos hacer.

 

[paliman]

Hola. No me contestaste, pero creo que te puedo dar una mano. O por lo menos una pista.

Sugiero usar SUMAPRODUCTO en lugar de una fórmula matricial:


=REDONDEAR(SUMAPRODUCTO((IZQUIERDA(B5336;2)=IZQUIERDA($B$5681:B24784;2))*(IZQUIERDA(A5336;2)=IZQUIERDA($A$5681:A24784;2))*($I$5681:I24784)) / SUMAPRODUCTO((IZQUIERDA(B5336;2)=IZQUIERDA($B$5681:B24784;2))*(IZQUIERDA(A5336;2)=IZQUIERDA($A$5681:A24784;2)));0)

Creo que no me faltó ningún paréntesis. Cualquier cosa volvé a escribir.

 

[asnieto]

Hola
lamento no haber contestado antes, no habia podido entrar.

Muchas gracias la formula funcionó bien pero quisiera leer un poco sobre esta formula, porque no entiendo como funciona, me podrias indicar donde hallar informacion adicional a la de la ayuda

Gracias

 

[paliman]

El único sitio que se me ocurre es la sección de artículos de Mr Excel. Seguramente allí debe haber algo. De todos modos, voy a tratar de explicarte cómo entiendo yo que trabaja SUMAPRODUCTO (yo me rompí la cabeza un buen tiempo hasta que me dí cuenta de cómo era).

Fijate en la siguiente tabla:

Sumaproducto.xls
	A	B	C	D
1	gris	10	54	VERDADERO
2	gris	20	60	FALSO
3	gris	10	32
4	gris	20	16
5	verde	10	15
6	verde	20	33
7	verde	10	20
8	verde	20	14
9
10		Suma	86
11		Cuenta	2
Hoja1

La fórmula SUMAPRODUCTO(B1:C2) me va a dar por resultado 1740. La cuenta que hace excel es la siguiente:

(10*54)+(20*60)=1740

Es decir, que va multiplicando por filas y luego suma el producto de cada fila.

Ahora bien. Fijate las celdas D1 y D2. En ambas celdas se prueba una condición. Donde la condición se cumple, excel te devuelve “VERDADERO” y donde no, te devuelve “FALSO”.

Ahora fijate la fórmula en C10. En esta fórmula cada término de SUMAPRODUCTO tiene una condición que debe cumplir, Excepto el último. Como te dije recién, cuando una condición se cumple excel te devuelve “VERDADERO”, de modo que para la primera fila de la matriz, la cuenta resulta:

VERDADERO * VERDADERO * 54

Y para la segunda fila:

VERDADERO * FALSO * 60

El secreto está en que excel “ve” los verdaderos como “1” y los falsos como “0”. Con lo cual, las cuentas nos quedan así:

1º fila: 1*1*54=54
2º fila: 1*0*60=0

Como ves, si en una fila hay alguna condición que no se cumpla, el resultado de esa fila es CERO, de modo que no cuenta en la suma final. Fijate también que el último término (la columna que se va a sumar) no lleva condición; de este modo se evita que se transforme en unos y ceros.
Si en cambio omitís este último término, excel va a sumar un 1 por cada fila que cumpla con TODAS las condiciones y un 0 por cada fila en la que por lo menos una de las condiciones no se cumpla. De esta forma lográs que SUMAPRODUCTO reemplace a la función CONTAR.SI.

La fórmula que te pasé está compuesta por un cociente entre dos funciones SUMAPRODUCTO. La primera (el numerador) suma los valores de aquéllas filas que cumplen con las condiciones impuestas. La segunda (el denominador) cuenta la cantidad de filas que las cumplen. Del cociente surge el promedio.

Espero que haya sido claro y perdón por lo largo del mensaje.

 

[asnieto]

No faltaba mas, es apenas lo necesario para que lo entienda. muchas gracias. ahora entiendo porque aveces las formulas con denominador logico me dan div/0.

De nuevo gracias