Change color of single Note Indicator triangle?

[jmpatrick]

Good morning!

I've been searching for a way to change the color of specific Note Indicators. I found this solution searching Microsoft's support site. It works fine but it changes every Note Indicator on the sheet.

I'm trying to only change the color of the Note Indicator on the selected cell. Here's the code:

Sub ReformatNoteIndicator()

Dim ws As Worksheet
Dim cmt As Comment
Dim rngCmt As Range
Dim shpCmt As Shape
Dim shpW As Double
Dim shpH As Double

Set ws = ActiveSheet
shpW = 5
shpH = 5

For Each cmt In ws.Comments
  Set rngCmt = cmt.Parent
  With rngCmt
    Set shpCmt = ws.Shapes.AddShape(msoShapeRightTriangle, rngCmt.Offset(0, 1).Left - shpW, .Top, shpW, shpH)
  End With
  With shpCmt
    .Flip msoFlipVertical
    .Flip msoFlipHorizontal
    .Fill.ForeColor.SchemeColor = 12
    .Fill.Visible = msoTrue
    .Fill.Solid
    .Line.Visible = msoFalse
  End With
Next cmt

End Sub

 

[Peter_SSs]

I'm trying to only change the color of the Note Indicator on the selected cell.

Try this modification of that code.

Sub Test()
  Dim shpCmt As Shape
  Dim shpW As Double
  Dim shpH As Double

  shpW = 5
  shpH = 5

  With ActiveCell
    If Not .Comment Is Nothing Then
      Set shpCmt = .Parent.Shapes.AddShape(msoShapeRightTriangle, .Offset(0, 1).Left - shpW, .Top, shpW, shpH)
      With shpCmt
        .Flip msoFlipVertical
        .Flip msoFlipHorizontal
        .Fill.ForeColor.SchemeColor = 12
        .Fill.Visible = msoTrue
        .Fill.Solid
        .Line.Visible = msoFalse
      End With
    End If
  End With
End Sub

 

[jmpatrick]

Try this modification of that code.

Sub Test()
  Dim shpCmt As Shape
  Dim shpW As Double
  Dim shpH As Double

  shpW = 5
  shpH = 5

  With ActiveCell
    If Not .Comment Is Nothing Then
      Set shpCmt = .Parent.Shapes.AddShape(msoShapeRightTriangle, .Offset(0, 1).Left - shpW, .Top, shpW, shpH)
      With shpCmt
        .Flip msoFlipVertical
        .Flip msoFlipHorizontal
        .Fill.ForeColor.SchemeColor = 12
        .Fill.Visible = msoTrue
        .Fill.Solid
        .Line.Visible = msoFalse
      End With
    End If
  End With
End Sub

Perfect! Thanks so much.

 

[Peter_SSs]

You're welcome. Thanks for the follow-up.

 

[jmpatrick]

You're welcome. Thanks for the follow-up.

Let me know if this requires a new post. Is it possible to delete the shape in the active cell? Similar to this (which deletes every shape):

Sub RemoveIndicatorShapes()

Dim ws As Worksheet
Dim shp As Shape

Set ws = ActiveSheet

For Each shp In ws.Shapes
If Not shp.TopLeftCell.Comment Is Nothing Then
  If shp.AutoShapeType = _
    msoShapeRightTriangle Then
    shp.Delete
  End If
End If
Next shp
    
End Sub

 

[jkpieterse]

Add

If Shp.TopLeftCell.Address = ActiveCell.Address Then

 

[jmpatrick]

Add

If Shp.TopLeftCell.Address = ActiveCell.Address Then

Works great. Thanks.