Code advice for Match then populate userform

[ipbr21054]

Evening,
Can you assist please.

I have a worksheet which has values in the cells.
I would open my userform & type a value consisting of letters & numbers in TextBox 1
Pressing the command button the code would look for this value in column A and then populate the other Textboxes from info on worksheet.

Here is some info for you.

Worksheet caled KEYLESS
Userform called HondaKeylessForm
Command Button is called LoadInfo
On the worksheet column A has part numbers A3 & down the page.
The related info is as shown below.

TextBox 1 = Column A
TextBox 2 = Column C
TextBox 3 = Column E
TextBox 4 = Column G
TextBox 5 = Column I
TextBox 6 = Column K
TextBox 7 = Column M

So if i type 72147 ABC 123 in TextBox 1 the code should look at my worksheet for a match.
Once the match is found then put the value from that rows column into the Textbox.

Many thanks

 

[DanteAmor]

Try this

Private Sub CommandButton1_Click()
  If TextBox1.Value = "" Then
    MsgBox "Fill textbox1"
    TextBox1.SetFocus
    Exit Sub
  End If
  
  Dim f As Range, sh As Worksheet
  Set sh = Sheets("KEYLESS")
  Set f = sh.Range("A:A").Find(TextBox1.Value, , xlValues, xlWhole)
  If Not f Is Nothing Then
    TextBox2 = sh.Cells(f.Row, "C")
    TextBox3 = sh.Cells(f.Row, "E")
    TextBox4 = sh.Cells(f.Row, "G")
    TextBox5 = sh.Cells(f.Row, "I")
    TextBox6 = sh.Cells(f.Row, "K")
    TextBox7 = sh.Cells(f.Row, "M")
  Else
    MsgBox "Does not exists"
  End If
End Sub

 

[ipbr21054]

Evening @DanteAmor
Just a thought.

I might also add a photo.
Can I use a TextBox to display the photo in ?

If so TextBox8 would be where it will be shown BUT column O would be the path to the photo on the pc.

Photos are 640x480
Should a photo be a touch bigger can we apply a code to force it to 640x480 or does it not just show the way excess ?

 

[DanteAmor]

Can I use a TextBox to display the photo in ?

For that use the image control.
Note: In column O, you must have path, file name and file extension, example: C:\files\images\photo1.jpg

Try this

Private Sub CommandButton1_Click()
  If TextBox1.Value = "" Then
    MsgBox "Fill textbox1"
    TextBox1.SetFocus
    Exit Sub
  End If
  
  Dim f As Range, sh As Worksheet, sFile As String
  Set sh = Sheets("KEYLESS")
  Set f = sh.Range("A:A").Find(TextBox1.Value, , xlValues, xlWhole)
  If Not f Is Nothing Then
    TextBox2 = sh.Cells(f.Row, "C")
    TextBox3 = sh.Cells(f.Row, "E")
    TextBox4 = sh.Cells(f.Row, "G")
    TextBox5 = sh.Cells(f.Row, "I")
    TextBox6 = sh.Cells(f.Row, "K")
    TextBox7 = sh.Cells(f.Row, "M")
    sFile = sh.Cells(f.Row, "O")
    If Dir(sFile) <> "" Then
      Image1.PictureSizeMode = fmPictureSizeModeStretch
      Image1.Picture = LoadPicture(sFile)
    End If
  Else
    MsgBox "Does not exists"
  End If
End Sub