COUNTIFS Excluding Range

[uk747]

COUNT Cat in A if B is a - =COUNTIFS(A2:A11,"Cat", B2:B11, "a")
COUNT Cat in A if B is a BUT Exclude if Column C is an x, y or z =COUNTIFS(A2:A11,"Cat", B2:B11, "a", C2:C11, "<>x", C2:C11, "<>y", C2:C11, "<>z")

Was wondering if my range was very long is there a way to add the range in formula, something like
=COUNTIFS(A2:A11,"Cat", B2:B11, "a", C2:C11 Doesn't CONTAIN anyting in Range E2:E4



Range is A2:E11

cat	a	x		x
dog	b	v		y
cat	a	y		z
cat	b	z
apple	a	x
banana	d	y
cherry	c	z
cat	b	z
cat	a	p
cat	a	t

 

[DanteAmor]

How about:

Dante Amor
	A	B	C	D	E	F
1
2	cat	a	x		x	4
3	dog	b	v		y
4	cat	a	y		z
5	cat	a	m
6	apple	a	x
7	cat	a	m
8	cherry	c	z
9	cat	a	x
10	cat	a	p
11	cat	a	t
Hoja1

Cell Formulas
Range	Formula
F2	F2	=SUMPRODUCT((A2:A11="cat")*(B2:B11="a")*(NOT(ISNUMBER(MATCH(C2:C11,E2:E4,0)))))

 

[johnmpl]

Hi, @uk747

Two options:

=SUM(COUNTIFS(A2:A11,"cat",B2:B11,"a",C2:C11,HSTACK(G2:G4,"*"))*{-1,1})
=SUMPRODUCT(--(A2:A11="cat"),--(B2:B11="a"),1-COUNTIF(G2:G4,C2:C11))

Blessings!

 

[uk747]

Thanks
All 3 worked (after editing G2:G4 range to E2:E4 for johnmpl solution)