CSV data to Array help

[JumboCactuar]

Hi,
I have data in the following format and want to store the data of each order in an array but unsure how to code that

example data
i want a 2D array which stores the Item + QTY of each order
Item is unique on each order line

What i am attempting is to have a userform list all of the orders in one listbox, then when a row is clicked on it displays the order data

OrderNo	Item	QTY
G6RX6TVB	CV54	1​
G6RX6TVB	FV55	4​
G6RX6TVB	CG55	1​
G6RX6TVB	TG62	6​
G6RX6TVB	RF22	7​
G6RX6TVB	RT43	2​
G6RX6TVB	TG62	1​
G6RX6TVB	FR78	1​
G6RX6TVB	DR44	5​
G6RX6TVB	FV55	1​
F7TVF56F	RT43	1​
F7TVF56F	TG62	2​
F7TVF56F	FD56	3​
F7TVF56F	VF55	4​
F7TVF56F	DR44	1​
F7TVF56F	HN66	3​
F7TVF56F	AC47	4​
F7TVF56F	CG55	1​
F7TVF56F	FH63	2​
F7TVF56F	JH52	3​
C54FGBV6	CG55	2​
C54FGBV6	RF22	2​
C54FGBV6	RT43	6​
C54FGBV6	TG62	3​
C54FGBV6	DR44	3​
C54FGBV6	AC47	1​

appreciate any help

 

[JumboCactuar]

something like this:

 

[Akuini]

Here's an example:
Note: data must be sorted by column A, if you want can add some lines in the the code to sort the data.
The workbook:

JumboCactuar

MediaFire is a simple to use free service that lets you put all your photos, documents, music, and video in a single place so you can access them anywhere and share them everywhere.

www.mediafire.com

Option Explicit
'NOTE: DATA MUST BE SORTED BY COLUMN A
Dim va
Dim d As Object

Private Sub UserForm_Initialize()
    Dim i As Long, j As Long
    With Sheets("Sheet1")  'change to suit
        va = .Range("A2", .Cells(.Rows.Count, "C").End(xlUp)) 'data in col A:C, start at row 2
    End With
    
    
    ListBox1.ColumnCount = 1
    ListBox2.ColumnCount = 2
    ListBox1.ColumnWidths = "150,30"
    
    Set d = CreateObject("scripting.dictionary"):    d.CompareMode = vbTextCompare

    For i = 1 To UBound(va, 1)
     j = i
        Do
            i = i + 1
            If i > UBound(va, 1) Then Exit Do
        Loop While va(i, 1) = va(i - 1, 1)
        i = i - 1
        d(va(i, 1)) = j & " : " & i
    Next
    ListBox1.List = d.keys
    
End Sub

Private Sub ListBox1_Change()
Dim z, vb, i As Long, k As Long
Dim tx As String

Application.StatusBar = ListBox1.ListIndex
tx = ListBox1.List(ListBox1.ListIndex, 0)

If d.Exists(tx) Then
    z = Split(d(tx), ":")
    ReDim vb(1 To (z(1) - z(0) + 1), 1 To 2)

    For i = z(0) To z(1)
        k = k + 1
        vb(k, 1) = va(i, 2)
        vb(k, 2) = va(i, 3)
    Next

End If

ListBox2.List = vb
End Sub

 

[Akuini]

Sorry, this line:
ListBox1.ColumnWidths = "150,30"
should be
ListBox2.ColumnWidths = "150,30"

Also we don't need this line:
Application.StatusBar = ListBox1.ListIndex

 

[JumboCactuar]

@Akuini
perfect thankyou

i've studied and understand how this works

 

[Akuini]

You're welcome, glad to help & thanks for the feedback.