Download only some formats

[josros60]

Hi,

how can I modify this vba code to just download the following attachments when email is receive, format like .pdf, .xlsx, .doc and .zip format?

this is the code I have now:

Public Sub saveAttachtoDiskNew(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
Dim dateFormat
    dateFormat = Format(Now, "yyyy-mm-dd H-mm")
saveFolder = "C:\EMAIL_ATTACHMENTS"

     For Each objAtt In itm.Attachments
     
     objAtt.SaveAsFile saveFolder & "\" & dateFormat & objAtt.DisplayName
          'objAtt.SaveAsFile saveFolder & "\" & objAtt.DisplayName
          Set objAtt = Nothing
     Next
End Sub

thank you

 

[smozgur]

I would use a helper function as shown below:

Public Sub saveAttachtoDiskNew(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
Dim dateFormat
    dateFormat = Format(Now, "yyyy-mm-dd H-mm")
    saveFolder = "C:\EMAIL_ATTACHMENTS"

     For Each objAtt In itm.Attachments
        If isMyAttachment(objAtt) Then
            objAtt.SaveAsFile saveFolder & "\" & dateFormat & objAtt.DisplayName
        End If
     Next
End Sub

Private Function isMyAttachment(objAtt As Outlook.Attachment) As Boolean
Dim arrTypes As Variant
Dim i As Integer
    arrTypes = Array("pdf", "xlsx", "doc", "zip")
    For i = 0 To UBound(arrTypes)
        If Right(objAtt.Filename, Len(arrTypes(i))) = arrTypes(i) Then
            isMyAttachment = True
            Exit Function
        End If
    Next i
End Function

 

[Dan_W]

Hi. I haven't tested it yet, but this should work:

Public Sub saveAttachtoDiskNew(itm As Outlook.MailItem)

    Dim objAtt As Outlook.Attachment
    Dim saveFolder As String
    Dim dateFormat As String
    
    Dim varExtension As Variant
    Dim attExtension As String
    
    
    dateFormat = Format(Now, "yyyy-mm-dd H-mm")
    saveFolder = "C:\EMAIL_ATTACHMENTS"

    For Each objAtt In itm.Attachments
        varExtension = Split(objAtt.DisplayName, ".")
        attExtension = varExtension(UBound(varExtension))
        Select Case LCase(attExtension)
            Case "pdf", "xlsx", "zip", "doc"
                objAtt.SaveAsFile saveFolder & "\" & dateFormat & objAtt.DisplayName
            Case Else
                ' Do nothing
        End Select
    Next
    Set objAtt = Nothing
End Sub

 

[Dan_W]

Oops - I was too slow - that'll teach me for getting a cup of tea!

 

[smozgur]

@Dan_W - I surely like your way better than mine and it is a better answer.
I somehow never feel closer with Select Case

Edit: It is a better answer, mainly because (there are other reasons too, but these are the main ones):
1- It is not executing an unnecessary loop.
2- It is using LCase to make sure about the upper case file names.

 

[Dan_W]

Thank you, but I agree - I never feel comfortable with Select Case - I can't explain it, it just feels like I'm being lazy or something?! Actually, my usual way of dealing with it is exactly the way you've done it (Array).

 

[smozgur]

I can't explain it

I can't explain either. I am sure it is just a habit by the way. It probably let me down in my earlier programming days by using it incorrectly, so I tried to keep away from it since then, not sure.

 

[josros60]

Thank you both, worked perfectly.

 

[smozgur]

Thank you both, worked perfectly.

Glad to hear it helps, @josros60.
Please remember to mark @Dan_W's post (post #3) as the solution to help future readers by simply clicking on the checkmark button next to the post.