Excel Macro to Print a Document In Word Works - But Hangs When Word is Already Open

[StephenBart]

I have built a excel loader to populate customer proposals from data in created in an excel workbook. The macro opens a mail merge word template and names it with path and filenamed based on the contents of cell values.

Macro work great but hangs in Word is already open - any idea how to fix this - i'd rather not have to close word every time Ii run the macro?

Sub CreateNewCBO()
'
' Creates CBO Onboarding Package for JPVI
'
Dim iApp As Word.Application
Dim iDoc As Word.Document
Dim FileName As String
Dim Path As String
Path = Range("c112") & "\3-CBO_Binder\"
FileName = Range("c116")
Set iApp = CreateObject("Word.Application")
iApp.Visible = True
iApp.Activate
Set iDoc = iApp.Documents.Add(Template:="U:\1000 ADMIN\1990 Templates\FORM_re_CBOName-CBO-Onboarding-Package.dotx", NewTemplate:=False, DocumentType:=0)
iDoc.SaveAs2 FileName:=Path & "000_" & FileName & ".docx", FileFormat:=wdFormatXMLDocument, AddtoRecentFiles:=False
End Sub

 

[NdNoviceHlp]

Hi StephenBart. This is sort of the standard way to prevent this type of error. HTH. Dave

Dim iApp As Object
'open Word application
On Error Resume Next
Set iApp = GetObject(, "Word.Application")
If Err.Number <> 0 Then
On Error GoTo 0
Set iApp = CreateObject("Word.Application")
End If
iApp .Visible = True

ps. Please use code tags

 

[StephenBart]

Thank you Dave - sorry but what does use code tags mean.

do i just add thus at the beginning of my code?

 

[Fluff]

Have a look here How to Post Your VBA Code

 

[NdNoviceHlp]

Ok. Here's the whole thing. This does leave the doc open and the Word application running. Dave

Sub CreateNewCBO()
'
' Creates CBO Onboarding Package for JPVI
'
Dim iApp As Object
Dim iDoc As Word.Document
Dim FileName As String
Dim Path As String
Path = Range("c112") & "\3-CBO_Binder\"
FileName = Range("c116")
'open Word application
On Error Resume Next
Set iApp = GetObject(, "Word.Application")
If Err.Number <> 0 Then
On Error GoTo 0
Set iApp = CreateObject("Word.Application")
End If
iApp .Visible = True
Set iDoc = iApp.Documents.Add(Template:="U:\1000 ADMIN\1990 Templates\FORM_re_CBOName-CBO-Onboarding-Package.dotx", NewTemplate:=False, DocumentType:=0)
iDoc.SaveAs2 FileName:=Path & "000_" & FileName & ".docx", FileFormat:=wdFormatXMLDocument, AddtoRecentFiles:=False
End Sub

 

[StephenBart]

Dave.

Thank you very much. This works great.

Ps Sorry about the code tag - will use in future.

Have a great day!

 

[NdNoviceHlp]

You are welcome. Thanks for posting your outcome. Dave