Greater than Less than troubles

[heilagr]

I am struggling with getting the correct month to display with my less than/greater than formula. I want it to display the previous month if the number in the cell its pulling from is less than 15 and to display the current month if the number in the cell is greater than 15.

Theoretically my formula should display "April" if the number in cell AZ20 is less than 15 and should display "May" if the number in cell AZ20 is greater than 15. Instead it is displaying "May" no matter what the number in cell AZ20 is (manually changed the date on my computer to test the formula - also tried in airplane mode to see if that made a difference). If I reverse the </> "April" will show no matter what the number is in cell AZ20.

I've included screenshots of both the correct </> and reversed with today's date and with the date bumped forward to show the change between reverse </> and no change despite the number in cell AZ20 being different. Where am I going wrong??

My formula is:

=IF(15<AZ20,(TEXT(TODAY(),"MMMM")),IF(15>AZ20,(TEXT(TODAY()-DAY(TODAY()),"MMMM"))))

Cell AZ20 is a formula that displays the current date:

=TEXT(TODAY(),"DD")

 

[Max1616]

When I test the formula it works fine for me. Perhaps the spreadsheet's calculations have been turned to manual? Can you check this:
Ribbon -> Formulas -> Calculation Options -> Should be automatic:

If it's on manual, it will not recalulcate the output of the formula when you change cells.

 

[Fluff]

Hi & welcome to Mr Excel.
If this is the formula in AZ20 =TEXT(TODAY(),"DD") then it will always be greater than 15 as it returns text & not a number.
Try using

=TEXT(TODAY(),"DD")+0

 

[Alex Blakenburg]

Following on from @Fluff's insight.
If you don't want to change AZ20 then change your formula to something like this:-

=IF(VALUE(AZ20)>15,TEXT(TODAY(),"MMMM"),TEXT(TODAY()-DAY(TODAY()),"MMMM"))

You could change AZ20 to something like this which returns a number:-

=DAY(TODAY())

In which case you can drop the VALUE from the above formula and use:-

=IF(AZ20>15,TEXT(TODAY(),"MMMM"),TEXT(TODAY()-DAY(TODAY()),"MMMM"))

 

[heilagr]

Following on from @Fluff's insight.
If you don't want to change AZ20 then change your formula to something like this:-

=IF(VALUE(AZ20)>15,TEXT(TODAY(),"MMMM"),TEXT(TODAY()-DAY(TODAY()),"MMMM"))

You could change AZ20 to something like this which returns a number:-

=DAY(TODAY())

In which case you can drop the VALUE from the above formula and use:-

=IF(AZ20>15,TEXT(TODAY(),"MMMM"),TEXT(TODAY()-DAY(TODAY()),"MMMM"))

This worked! Thank you so much! This was driving me crazy

 

[Alex Blakenburg]

Thanks for letting us know. Glad we could help.