Help with making the formula a Dynamic Array

[Stephen_IV]

I am trying to make a Dynamic Array formula for the data below. Any help would be appreciated! Thanks in advance!

Dynamic Array Min.xlsm
	A	B	C	D	E	F
1		AL	Joe	Bob	John	Lowest Score
2	1st Hole	3	5	1	2	Bob
3	2nd Hole	5	3	4	3	Joe, John
4	3rd Hole	2	4	2	2	AL, Bob, John
5	4th Hole	2	3	2	2	AL, Bob, John
6	5th Hole	4	3	4	4	Joe
7	6th Hole	2	2	4	5	AL, Joe
8	7th Hole	4	2	2	2	Joe, Bob, John
9	8th Hole	2	4	2	5	AL, Bob
10	9th Hole	2	3	2	3	AL, Bob
11	10th Hole	7	3	3	4	Joe, Bob
12	11th Hole	2	5	3	2	AL, John
13	12th Hole	5	4	4	5	Joe, Bob
14	13th Hole	3	3	3	2	John
15	14th Hole	6	2	3	3	Joe
16	15th Hole	4	4	3	5	Bob
17	16th Hole	3	3	3	3	AL, Joe, Bob, John
18	17th Hole	2	3	3	4	AL
19	18th Hole	3	3	3	1	John
Sheet2

Cell Formulas
Range	Formula
F2:F19	F2	=TEXTJOIN(", ",TRUE,IF(B2:E2=MIN(B2:E2),$B$1:$E$1,""))

 

[Skybluekid]

Hi, the formula that you have posted seems ok. What is it you are trying to achieve?

 

[Peter_SSs]

What is it you are trying to achieve?

I am trying to make a Dynamic Array formula for the data below.

Try this

(BTW, I hope you have a special prize for Bob & John )

23 01 21.xlsm
	B	C	D	E	F
1	AL	Joe	Bob	John	Lowest Score
2	3	5	1	2	Bob
3	5	3	4	3	Joe, John
4	2	4	2	2	AL, Bob, John
5	2	3	2	2	AL, Bob, John
6	4	3	4	4	Joe
7	2	2	4	5	AL, Joe
8	4	2	2	2	Joe, Bob, John
9	2	4	2	5	AL, Bob
10	2	3	2	3	AL, Bob
11	7	3	3	4	Joe, Bob
12	2	5	3	2	AL, John
13	5	4	4	5	Joe, Bob
14	3	3	3	2	John
15	6	2	3	3	Joe
16	4	4	3	5	Bob
17	3	3	3	3	AL, Joe, Bob, John
18	2	3	3	4	AL
19	3	3	3	1	John
Lowest

Cell Formulas
Range	Formula
F2:F19	F2	=BYROW(B2:E19,LAMBDA(rw,TEXTJOIN(", ",,FILTER(B1:E1,rw=MIN(rw)))))
Dynamic array formulas.

 

[Stephen_IV]

LOL!!! Thank you Peter_SSs. That is exactly what I needed! I just came up with something that is nowhere near as robust as yours! I always appreciate your posts and learned a lot from you! Thanks again!

=BYROW(IF(B2:E19=BYROW(B2:E19,LAMBDA(x,MIN(x))),$B$1:$E$1,""),LAMBDA(x,TEXTJOIN(", ",1,x)))

 

[Peter_SSs]

You're welcome. Thanks for the follow-up.