How do reference any cell in a table column

[dpaton05]

I have an excel table called css_quote and while reviewing the code, I realised that part of it is wrong.

I have the following code:

Private Sub cmdSendTCTPrint_Click()
    Costing.Unprotect password:=ToUnlock
    Quoting.Unprotect password:=ToUnlock
        If Range("A11").Value = "" Then
            MsgBox "Please enter a date for every service"
            Exit Sub
        End If
        Call cmdSend
        Quoting.Activate
        Call AddReference
    Quoting.Protect password:=ToUnlock
    Costing.Protect password:=ToUnlock
End Sub

Row 11 is the first row of the table with A being the date. This works if there is only 1 row but if there are multiple rows and the date is missing on rows other than the first, it won't pick up that the date is missing on the additional rows. What is the syntax to see if there are any blank cells in row A of the table?

 

[JoeMo]

In this snippet, N is the number of empty table cells in column A of the table whose name is "css_quote" and is on the active sheet when the code is executed.

Sub test()
Dim LO As ListObject, N As Long
Set LO = ActiveSheet.ListObjects("css_quote")
N = LO.DataBodyRange.Rows.Count - Application.CountA(LO.DataBodyRange.Columns(1))
MsgBox "There are " & N & " empty table cells in column A"
End Sub

 

[dpaton05]

Thanks Joe,

Sorry, I do not really follow.

Where I have my line of code

If Range("A11").Value = "" Then

How could ask, not just is A11 empty as I have in my code, but is any cell empty in column 1 of css_quote?

 

[dpaton05]

I worked it out, thanks Joe.

 

[Peter_SSs]

You could also target the empty cells (I am assuming they do not contain formulas returning "") more directly, like this.

Sub CheckEmptyCells()
  Dim rEmpty As Range
  
  On Error Resume Next
  Set rEmpty = Range("css_quote[Date]").SpecialCells(xlBlanks)
  On Error GoTo 0
  If Not rEmpty Is Nothing Then MsgBox "Please enter a date for every service. Check the following cells:" & vbLf & rEmpty.Address(0, 0)
End Sub