How to eliminate characters from a textbox

[Pookiemeister]

Private Sub txtbxPrdctName_Exit(ByVal Cancel As MSForms.ReturnBoolean)
   
    If Len(txtbxPrdctName.Value) > 2 Then
        Me.txtbxPrdctName.Value = StrConv(Me.txtbxPrdctName.Value, vbProperCase) & " " & Me.txtbxMgAmt.Value & " " & Me.txtbxCnt.Value
        Me.txtbxTYRD.Value = Replace(Me.txtbxPrdctName.Value, "8ct", " ")
    End If
   
End Sub

The question I have is with the code below:

Me.txtbxTYRD.Value = Replace(Me.txtbxPrdctName.Value, "8ct", " ")

The above code works and removes the "8ct" but I was wondering if there was a way to replace/remove any number entered if followed with the letters "ct". The potential problem is that number could vary from a one digit number to a three digit number. I tried the following codes but neither worked.

Me.txtbxTYRD.Value = Replace(Me.txtbxPrdctName.Value, "###" & "ct", " ")
Me.txtbxTYRD.Value = Replace(Me.txtbxPrdctName.Value, "###ct", " ")

Thank you

 

[GWteB]

How about this ....

Private Sub txtbxPrdctName_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    With Me.txtbxPrdctName
        If Len(.Value) > 2 Then
            .Value = StrConv(.Value, vbProperCase) & " " & Me.txtbxMgAmt.Value & " " & Me.txtbxCnt.Value
            Me.txtbxTYRD.Value = Strip_Ct(.Value)
        End If
    End With
End Sub

using the function below

Public Function Strip_Ct(ByVal argStr As String) As String

    Const ct    As String = "ct"
    Dim x       As Long
    Dim i       As Long

    x = InStr(1, argStr, ct, vbTextCompare)
    For i = x To 1 Step -1
        If Not IsNumeric(Mid(argStr, i - 1, 1)) Then
            Strip_Ct = Left(argStr, i - 1) & Right(argStr, Len(argStr) - x - 1)
            Exit For
        End If
    Next i
End Function

 

[Pookiemeister]

That seems to work. Thank you very much.

 

[GWteB]

You're welcome. On second thougt the previous code has a flaw. A TextBox value of "the actual price is 88ct." results in a TextBox value of "the aual price is ." I have solved this shortcoming below, although the result may still contain excess spaces.

Public Function Strip_Ct(ByVal argStr As String) As String

    Const ct    As String = "ct"
    Dim x       As Long
    Dim i       As Long

    x = InStr(1, argStr, ct, vbTextCompare)
    For i = x To 1 Step -1
        If Not IsNumeric(Mid(argStr, i - 1, 1)) Then
            If x <> i Then
                Strip_Ct = Left(argStr, i - 1) & Right(argStr, Len(argStr) - x - 1)
                Exit For
            Else
                Strip_Ct = argStr
                Exit For
            End If
        End If
    Next i
End Function

 

[Pookiemeister]

Your original code seems to be working as expected. No errors, but thank you for the update.