How to Move Subset of Data from Column to Rows

[ohalloran_b]

Hi Guys,
I've a scenario where I need to download data from a new tool, send it out to vendors for updates and then upload data back into the tool. Problem is the upload cannot be in the same layout as the download.
I'm having trouble automating the change in layout, transposing won't work, anyone with any ideas?

Download Layout;
<style><!--table {mso-displayed-decimal-separator:"\."; mso-displayed-thousand-separator:"\,";}@page {margin:.75in .7in .75in .7in; mso-header-margin:.3in; mso-footer-margin:.3in;}td {padding-top:1px; padding-right:1px; padding-left:1px; mso-ignoreadding; color:windowtext; font-size:10.0pt; font-weight:400; font-style:normal; text-decoration:none; font-family:Arial; mso-generic-font-family:auto; mso-font-charset:0; mso-number-format:General; text-align:general; vertical-align:top; border:none; mso-background-source:auto; mso-pattern:auto; mso-protection:locked visible; white-space:nowrap; mso-rotate:0;}.xl63 {mso-number-format:"Short Date"; text-align:right;}.xl64 {border:.5pt solid windowtext; background:#F2DCDB; mso-pattern:black none;}--></style>

Article	Supplier No	Hub 11	Hub 12	Hub 13	Hub 14
XX123ZM/A	00382601P	21/06/2017	21/06/2017	21/06/2017	21/06/2017
ZZ123ZM/A	00382601P	28/06/2017	28/06/2017	28/06/2017	28/06/2017
AA123ZM/A	00567001P	05/07/2017	05/07/2017	05/07/2017	05/07/2017

<!--StartFragment--> <colgroup><col width="87" span="6" style="width:65pt"> </colgroup><tbody>
<!--EndFragment--></tbody>

Upload Layout;

Article Number	Hub Code	Supplier Number	Supply Landing Date
XX123ZM/A	Hub 11	01234567P	21/06/2017
XX123ZM/A	Hub 12	01234567P	21/06/2017
XX123ZM/A	Hub 13	01234567P	21/06/2017
XX123ZM/A	Hub 14	01234567P	21/06/2017
ZZ123ZM/A	Hub 11	12345678P	28/06/2017
ZZ123ZM/A	Hub 12	12345678P	28/06/2017
ZZ123ZM/A	Hub 13	12345678P	28/06/2017
ZZ123ZM/A	Hub 14	12345678P	28/06/2017
AA123ZM/A	Hub 11	23456789P	05/07/2017
AA123ZM/A	Hub 12	23456789P	05/07/2017
AA123ZM/A	Hub 13	23456789P	05/07/2017
AA123ZM/A	Hub 14	23456789P	05/07/2017

<colgroup><col><col><col><col></colgroup><tbody>
</tbody>

 

[MickG]

Try this for results starting "H1".

[COLOR="Navy"]Sub[/COLOR] MG08Jun49
[COLOR="Navy"]Dim[/COLOR] Ray [COLOR="Navy"]As[/COLOR] Variant, n [COLOR="Navy"]As[/COLOR] [COLOR="Navy"]Long,[/COLOR] Ac [COLOR="Navy"]As[/COLOR] [COLOR="Navy"]Long,[/COLOR] c [COLOR="Navy"]As[/COLOR] [COLOR="Navy"]Long,[/COLOR] Ac2 [COLOR="Navy"]As[/COLOR] [COLOR="Navy"]Long[/COLOR]
Ray = Cells(1).CurrentRegion
ReDim nray(1 To UBound(Ray, 1) * UBound(Ray, 2), 1 To 4)
nray(1, 1) = "Article Number": nray(1, 2) = "Hub Code"
nray(1, 3) = "Supplier Number": nray(1, 4) = "Supply Landing Date"
c = 1
[COLOR="Navy"]For[/COLOR] n = 2 To UBound(Ray, 1)
    [COLOR="Navy"]For[/COLOR] Ac = 3 To UBound(Ray, 2)
       c = c + 1
        nray(c, 1) = Ray(n, 1)
        nray(c, 2) = Ray(1, Ac)
        nray(c, 3) = Ray(n, 2)
        nray(c, 4) = Ray(n, Ac)
    [COLOR="Navy"]Next[/COLOR] Ac
[COLOR="Navy"]Next[/COLOR] n
Range("H1").Resize(c, 4).Value = nray
[COLOR="Navy"]End[/COLOR] [COLOR="Navy"]Sub[/COLOR]

Regards Mick

 

[hiker95]

ohalloran_b,

Welcome to the MrExcel forum.


Where are you getting the Supplier Number's from for your Upload Layout?

 

[hiker95]

ohalloran_b,

Here is another macro solution for you to consider, that use two arrays in memory, that will adjust to the number of raw data rows, and, columns.

You can change the raw data worksheet name in the macro.

The macro will create a new worksheet Results.

Sample raw data:

Excel 2007
	A	B	C	D	E	F	G
1	Article	Supplier No	Hub 11	Hub 12	Hub 13	Hub 14
2	XX123ZM/A	00382601P	21/06/2017	21/06/2017	21/06/2017	21/06/2017
3	ZZ123ZM/A	00382601P	28/06/2017	28/06/2017	28/06/2017	28/06/2017
4	AA123ZM/A	00567001P	05/07/2017	05/07/2017	05/07/2017	05/07/2017
5
Sheet1

And, after the macro in a new worksheet Results:

Excel 2007
	A	B	C	D
1	Article Number	Hub Code	Supplier Number	Supply Landing Date
2	XX123ZM/A	Hub 11	00382601P	21/06/2017
3	XX123ZM/A	Hub 12	00382601P	21/06/2017
4	XX123ZM/A	Hub 13	00382601P	21/06/2017
5	XX123ZM/A	Hub 14	00382601P	21/06/2017
6	ZZ123ZM/A	Hub 11	00382601P	28/06/2017
7	ZZ123ZM/A	Hub 12	00382601P	28/06/2017
8	ZZ123ZM/A	Hub 13	00382601P	28/06/2017
9	ZZ123ZM/A	Hub 14	00382601P	28/06/2017
10	AA123ZM/A	Hub 11	00567001P	05/07/2017
11	AA123ZM/A	Hub 12	00567001P	05/07/2017
12	AA123ZM/A	Hub 13	00567001P	05/07/2017
13	AA123ZM/A	Hub 14	00567001P	05/07/2017
14
Upload

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

1. Copy the below code
2. Open your NEW workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

Sub ReorganizeData()
' hiker95, 06/08/2017, ME1008838
Dim w1 As Worksheet, wu As Worksheet
Dim a As Variant, i As Long, c As Long, lr As Long, lc As Long, n As Long
Dim o As Variant, j As Long
Application.ScreenUpdating = False
Set w1 = Sheets("Sheet1")     '<-- you can change the sheet name here
If Not Evaluate("ISREF(Upload!A1)") Then Worksheets.Add(After:=w1).Name = "Upload"
Set wu = Worksheets("Upload")
wu.UsedRange.Clear
With w1
  lr = .Cells(Rows.Count, 1).End(xlUp).Row
  lc = .Cells(1, Columns.Count).End(xlToLeft).Column
  a = .Range(.Cells(1, 1), .Cells(lr, lc))
  n = Application.CountA(.Range(.Cells(2, 3), .Cells(lr, lc)))
  ReDim o(1 To n + 1, 1 To 4)
  j = j + 1: o(j, 1) = "Article Number": o(j, 2) = "Hub Code"
  o(j, 3) = "Supplier Number": o(j, 4) = "Supply Landing Date"
End With
For i = 2 To lr
  For c = 3 To lc
    j = j + 1: o(j, 1) = a(i, 1): o(j, 2) = a(1, c): o(j, 3) = a(i, 2): o(j, 4) = a(i, c)
  Next c
Next i
With wu
  .Cells(1, 1).Resize(UBound(o, 1), UBound(o, 2)) = o
  .Cells(1, 1).Resize(, UBound(o, 2)).Font.Bold = True
  .UsedRange.Columns.AutoFit
  .Activate
End With
Application.ScreenUpdating = True
End Sub

Before you use the macro with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm, and, answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

Then run the ReorganizeData macro.

 

[ohalloran_b]

Thanks for all the feedback. I'll be trying these out today

 

[hiker95]

ohalloran_b,

You are very welcome. Glad we could help.

We will be watching for your next reply.